StreamingTemplateEngine exception MissingPropertyException - groovy

Question

How to avoid occurrence MissingPropertyException at absence of parameters from a template in Map and to replace not found values by null?
import groovy.text.StreamingTemplateEngine
import groovy.text.Template
class Test {
private static Writable binding(Map map, String string) {
Template template = new StreamingTemplateEngine().createTemplate(string)
return template.make(map)
}
static void main(String... args) {
def template = "\${test1} \${test2}"
def map = ["test1": "test1"]
print binding(map, template)
}
}

Answer 1

There is no configuration option to suppress this exception, however you can extend a map you pass to the template and change its behavior a bit. Consider following example:
import groovy.text.StreamingTemplateEngine
import groovy.text.Template
def string = '''
Dear <% out.print firstname %> ${lastname},
We <% if (accepted) out.print 'are pleased' else out.print 'regret' %>
to inform you that your paper entitled
'$title' was ${ accepted ? 'accepted' : 'rejected' }.
The conference committee.
'''
def map = [
firstname: 'test',
lastname: 'test',
accepted: true
]
Template template = new StreamingTemplateEngine().createTemplate(string)
println template.make(map)
It fails with the following exception:
Caught: groovy.text.TemplateExecutionException: Template execution error at line 4:
3: We <% if (accepted) out.print 'are pleased' else out.print 'regret' %> to inform you that your paper entitled
--> 4: '$title' was ${ accepted ? 'accepted' : 'rejected' }.
5:
groovy.text.TemplateExecutionException: Template execution error at line 4:
3: We <% if (accepted) out.print 'are pleased' else out.print 'regret' %> to inform you that your paper entitled
--> 4: '$title' was ${ accepted ? 'accepted' : 'rejected' }.
5:
at test.run(test.groovy:21)
Caused by: groovy.lang.MissingPropertyException: No such property: title for class: groovy.tmp.templates.StreamingTemplateScript1
... 1 more
It fails because we have defined 3 from 4 template variables (variable title is missing).
Solution: create wrapper for a Map
Let's fix it. We will do it by overriding map method containsKey(Object key) in a way that it always returns true (this method is used by the template engine and if it returns false, template engine throws an exception). We will create a wrapper class that encapsulates a map and delegates invocation of non existing methods to this wrapped class. We will call this class Bindings.
import groovy.text.StreamingTemplateEngine
import groovy.text.Template
class Bindings {
#Delegate private final Map map
Bindings(Map map) {
this.map = map
}
boolean containsKey(Object key) {
return true
}
}
def string = '''
Dear <% out.print firstname %> ${lastname},
We <% if (accepted) out.print 'are pleased' else out.print 'regret' %>
to inform you that your paper entitled
'$title' was ${ accepted ? 'accepted' : 'rejected' }.
The conference committee.
'''
def map = [
firstname: 'test',
lastname: 'test',
accepted: true
]
Template template = new StreamingTemplateEngine().createTemplate(string)
println template.make(new Bindings(map))
Output:
Dear test test,
We are pleased
to inform you that your paper entitled
'null' was accepted.
The conference committee.
There is no MissingPropertyException thrown anymore. However, as you can see, null is printed as null inside the String. If you would like to print an empty string instead, you can add Object get(Object key) method to Bindings and override its default behavior:
class Bindings {
#Delegate private final Map map
Bindings(Map map) {
this.map = map
}
boolean containsKey(Object key) {
return true
}
Object get(Object key) {
return map.getOrDefault(key, '')
}
}
If you do so, you will see the output similar to:
Dear test test,
We are pleased
to inform you that your paper entitled
'' was accepted.
The conference committee.
Hope it helps.

Answer 2

As an alternative, you can just use the groovy Map.withDefault method:
import groovy.text.StreamingTemplateEngine
import groovy.text.Template
def string = '''
Dear <% out.print firstname %> ${lastname},
We <% if (accepted) out.print 'are pleased' else out.print 'regret' %>
to inform you that your paper entitled
'$title' was ${ accepted ? 'accepted' : 'rejected' }.
The conference committee.
'''
def map = [
firstname: 'test',
lastname: 'test',
accepted: true
].withDefault { "<not found>" }
Template template = new StreamingTemplateEngine().createTemplate(string)
println template.make(map)
where the only change to the OPs code is the withDefault clause. Executing the above prints:
~> groovy test.groovy
Dear test test,
We are pleased
to inform you that your paper entitled
'<not found>' was accepted.
The conference committee.
As a side note, I wrote the streaming template engine as a contribution and a response to the limitations of the other template engines at the time a few years back. Glad to see it being used!
Though in hindsight it's far from perfect. Writing another one with a better internal approach has been on my list for aeons.