Cancelling GetSaveAsFilename - excel

Question

I have code, that only runs when a user chose "Save As". To do that and getting the new name of the file I'm using the Application.GetSaveAsFilename function.
The problem I came across was a type mismatch while checking if the user clicked on Cancel when he did not do that.
Line that threw the error when Cancel was not clicked: If saveName = False Then Exit Sub
My working code:
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
If Not SaveAsUI Then Exit Sub
Cancel = True
'other variables
Dim saveName As String
saveName = Application.GetSaveAsFilename(filefilter:="Microsoft Excel Files (*.xlsm), *.xlsm", Title:="Save as Microsoft Excel Macro-Enabled Worksheet")
On Error GoTo RunTime13
If saveName <> False Then
On Error GoTo 0
'other code
ThisWorkbook.SaveAs Filename:=saveName, FileFormat:=52
End If
Exit Sub
RunTime13:
If Err.Number = 13 Then Resume Next
End Sub
What am I doing wrong, that I have to work around the Cancel button like this?
Edit:
I chose Dim saveName As Variant to be able to use If saveName = False Then Exit Sub
As Vityata mentioned I am in Germany and thus could have run into problems with the language, fortunately for me Vityata reminded me of the problem because I am in fact using Excel in English, but not all of my colleagues are, so my accepted answer might not have worked when they were using the workbook.

Answer 1

As you've declared SaveName as a string, you need to check for "False", not False.
If saveName <> "False" Then

Answer 2

OP, I have some news for you - you are in Germany and thus I am about 99% sure you are using German Excel.
There the VBA is a bit translated, thus the saveName is translated to Falsch and not False as in the rest of the world. E.g. CStr(False) returns Falsch.
In your code write either of these three:
If saveName <> "Falsch"
If saveName <> False
If Len(saveName) <> 6

Answer 3

Here's another approach:
Dim vSaveName As Variant
vSaveName = Application.GetSaveAsFilename(filefilter:="Excel Files (*.xlsm), *.xlsm", _
Title:="Save as Macro-Enabled Worksheet")
If TypeName(vSaveName) = "Boolean" Then Exit Sub
'' otherwise continue with save...
The only time vSavename is a Boolean is when the user cancels, so this approach doesn't need to know how to say False in the user's language.