Why does my Cypher query not work? - node.js

Question

I am making a Node.js server which manipulates a Neo4j database. Now I have a system of admins and posts, admins add posts. This is currently what my graph looks like:
Now I want the network to be interconnected so I want to add a relationship between the Admin nodes "COLLEAGUE_OF". I wrote a Cypher query but I am getting a Cypher syntax error.
This is the syntax:
MERGE (c:Admin)
MERGE (n:BlogPost {mongoId:{idNeo}})
MERGE (b:Admin {mongoAdminId:{idNeoAd}})
MERGE(n)-[:ADDED_BY]->(b), (b)-[:COLLUEGE_OF]->(c)
This is the entire route which executes the syntax:
routes.post('/blogPosts/frontpage/:id/:aid', function (req, res) {
const id = req.param('id');
const aid = req.param('aid');
session
.run("MERGE (c:Admin) MERGE (n:BlogPost {mongoId:{idNeo}}) MERGE (b:Admin {mongoAdminId:{idNeoAd}}) MERGE(n)-[:ADDED_BY]->(b), (b)-[:COLLUEGE_OF]->(c)", {idNeo: id, idNeoAd: aid})
.then(function(result) {
res.status(200).json({"response": "BlogPost added to front page."});
session.close();
})
.catch((error) => {
res.status(400).json(error);
});
});

Answer 1

Assuming that :COLLUEGE_OF is the spelling you want (if this is in English, you may want :COLLEAGUE_OF instead), this query should take an existing graph of :Admin nodes and connect them to each other:
MATCH (c:Admin)
WITH collect(c) as admins
UNWIND admins as admin1
UNWIND admins as admin2
WITH admin1, admin2
WHERE id(admin1) < id(admin2) // prevents matching to the same pair with swapped order, and matching a node to itself
MERGE (admin1)-[:COLLUEGE_OF]-(admin2)
And this query would be used when adding a new blogpost and admin to the graph (it will not perform the merge if it has previously been processed):
MERGE (n:BlogPost {mongoId:{idNeo}})
MERGE (b:Admin {mongoAdminId:{idNeoAd}})
MERGE (n)-[:ADDED_BY]->(b)
WITH b
WHERE NOT (b)-[:COLLUEGE_OF]-()
MATCH (c:Admin)
WHERE c <> b
MERGE (b)-[:COLLUEGE_OF]-(c)
That said, if you really need :Admins to be connected to each other, it would be far easier to model this differently, with some kind of :ColleagueGroup node that all :Admins connect to, like this:
// create the single :ColleagueGroup node for all admins:
MERGE (group:ColleagueGroup)
WITH group
MATCH (c:Admin)
MERGE (c)-[:COLLUEGE_OF]->(group)
And then for adding a new admin
// add a new :Admin to the group
MERGE (n:BlogPost {mongoId:{idNeo}})
MERGE (b:Admin {mongoAdminId:{idNeoAd}})
WITH n, b
MATCH (group:ColleagueGroup)
MERGE (n)-[:ADDED_BY]->(b)
MERGE (b)-[:COLLUEGE_OF]->(group)
And for finding colleagues of a single :Admin node (which will be all :Admins):
MATCH (b:Admin {mongoAdminId:{idNeoAd}})-[:COLLUEGE_OF*2]-(colleague:Admin)
RETURN colleague

Answer 2

The problem is in the last line of your query, specifically, the , (b)-[:COLLUEGE_OF]->(c) statement, which creates a syntax error. Just remove the comma and add an additional merge statement.
MERGE (c:Admin)
MERGE (n:BlogPost {mongoId:{idNeo}})
MERGE (b:Admin {mongoAdminId:{idNeoAd}})
MERGE(n)-[:ADDED_BY]->(b)
MERGE(b)-[:COLLUEGE_OF]->(c)