VBA - 1 page setup different than rest (unknown #) pages - excel

Question

I am trying to do page setup on multiple sheets with same range. However, one of the sheets "Dashboard" has different page set up range. It is going to be "D24:K73" How can I accomplish that with the code below? I have tried modifying it but my skills do not produce wanted results.
Sub Octsaveaspdf()
Dim ws As Worksheet
Dim FileName As String
Dim FilePath As String
For Each ws In Sheets
If ws.Visible Then ws.Select (False)
Next
FilePath = Range("Instructions!B16").Value
FileName = Range("Dashboard!Q26").Text
Range("$p24:$w73").Select
Application.PrintCommunication = False
With ActiveSheet.PageSetup
LeftMargin = Application.CentimetersToPoints(0.1)
.RightMargin = Application.CentimetersToPoints(0.1)
.FitToPagesWide = 1
End With
Application.PrintCommunication = True
ActiveSheet.ExportAsFixedFormat _
Type:=xlTypePDF, FileName:=FilePath & "Compare " & FileName & ".pdf" _
, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End Sub
I truly appreciate all the help :) Thank you!

Answer 1

Move your export into a separate procedure and call it multiple times with different ranges to export.
The code below will work through each visible sheet and export different ranges depending on the sheet name.
Each export will be given the same name, so you'll need to do something about that to stop problems with file name conflicts.
Private FilePath As String
Private FileName As String
Public Sub OctSaveAsPDF()
Dim ws As Worksheet
FilePath = ThisWorkbook.Worksheets("Instructions").Range("B16")
FileName = ThisWorkbook.Worksheets("Dashboard").Range("Q26")
For Each ws In ThisWorkbook.Worksheets
If ws.Visible Then
Select Case ws.Name
Case "Dashboard"
PerformExport ws.Range("D24:K73")
Case "Sheet1", "Sheet2"
PerformExport ws.Range("A1:Z10")
Case Else
PerformExport ws.Range("P24:W73")
End Select
End If
Next ws
End Sub
Public Sub PerformExport(xpRng As Range)
With xpRng
With .Parent.PageSetup 'The parent of the range is the worksheet.
.LeftMargin = Application.CentimetersToPoints(0.1)
.RightMargin = Application.CentimetersToPoints(0.1)
.FitToPagesWide = 1
End With
.ExportAsFixedFormat _
Type:=xlTypePDF _
, FileName:=FilePath & "Compare " & FileName & ".pdf" _
, Quality:=xlQualityStandard _
, IncludeDocProperties:=True _
, IgnorePrintAreas:=False _
, OpenAfterPublish:=True
End With
End Sub