I have an excel sheet with the given date in Column A and B. I want to convert the same as shown on right side of the picture
If you wish to use formula approach, then please add this formula =IFERROR(INDEX($B$2:$B$14,SMALL(IF($D2=$A$2:$A$14,ROW($A$2:$A$14)-ROW($A$2)+1),COLUMN(A2))),"") in cell E2. When entering formula please use CTRL+SHIFT+ENTER combination, since this is array formula. After you confirmed formula, drag it across your area E2:H5.
Related
I'm trying to make a summary which list out all the matches and do a transpose of the table. I wrote a formula which works successfully. But, I come into another problem, which I find my formula cannot be dragged down and apply to all rows. Can anyone assist me in improving my formula?
Source:
Summary:
I would want to drag down the rows in "My summary" and the formula can do the columns+1 automatically. Appreciate for your help.
Here's my formula:
=IFERROR(INDEX(Sheet1!$F$9:$F$16, SMALL(IF(Sheet1!$H$9:$H$16="X",ROW(Sheet1!$H$9:$H$16)-ROW(Sheet1!H$9)+1),COLUMN(A1))),"")
In your screenshot it's difficult to tell which rows the data lives in. The following formula has been entered into Sheet2, cell B2 and copied down.
=IFERROR(TRANSPOSE(FILTER(Sheet1!$F$9:$F$16,INDEX(Sheet1!$H$9:$K$16,1,ROW(A1)):INDEX(Sheet1!$H$9:$K$16,8,ROW(A1))="x")),"")
Source screenshot Sheet1
Result screenshot Sheet 2
This approach uses Excel's Dynamic Array functionality, available only in Excel license with Office 365. The formula is only in column 2. It automatically spills its results into the neighboring columns as required.
edit after comment
If you don't have Office 365, you can use a variant of your formula, where the Index is replaced by and Index():Index() technique. The first Index pulls the first row, the second Index pulls the last row and the two results are combined with the range operator : that combines the two results into a range.
=IFERROR(INDEX(Sheet1!$F$9:$F$16,
SMALL(IF(INDEX(Sheet1!$H$9:$K$16,1,ROW(A1)):
INDEX(Sheet1!$H$9:$K$16,8,ROW(A1))="X",
ROW($A$9:$A$16)-ROW(A$9)+1),COLUMN(A1))),"")
Start in the first result cell (B2 in my screenshot) and use Ctrl+Shift+Enter to confirm, since it is an array formula. Then copy across and down.
Note: screenshot results are different, since I recreated the sample from scratch and the source data is different.
So my sheet looks like this:
I need to sum the values based on text in the products column.
Can someone explain to me how this is done without using VBA?
Enter the following formula in Cell B2
=SUM(IF(ISNUMBER(FIND(","& E$1:E$5&",",","&A2&",")),F$1:F$5))
This is an array formula so commit it by pressing Ctrl+Shift+Enter. Drag/Copy down as required. See image for reference.
Got this from here.
I have two columns of data in excel sheet- column A and column B. I want that the values which are in column a but not in column b, should appear column c. for example please look at this screen shoot-
http://imgur.com/a/qYmFF
THANK YOU VERY MUCH..
You can use this array formula in C2(it must be in C2 or the reference of $C$1:C1 must be changed to the cell directly above the first instance of this formula):
=IFERROR(INDEX($A$1:$A$10,MATCH(1,(COUNTIF($A$1:$A$10,$A$1:$A$10)<>COUNTIF($B$1:$B$6,$A$1:$A$10))*(COUNTIF($C$1:C1,$A$1:$A$9)<COUNTIF($A$1:$A$10,$A$1:$A$10)-COUNTIF($B$1:$B$6,$A$1:$A$10)),0)),"")
Being an array formula it must be confirmed with Ctrl-Shift-Enter instead of Enter when exiting edit mode. If done correctly then Excel will put {} around the formula.
Then copy/drag the formula down till you get blanks.
Please see the table :
Based on the table, I need to display only those brand of cars manufactured by maruti in column E. I used =VLOOKUP("maruti",A:C, 2, FALSE) but gives result only in one cell. When I drag it down, it brings in duplicate results. Where am I going wrong in this? Is Vlookup the correct formula to achieve my requirement?
OPTION 1)
IF formula
=IF(A1="Maruti",B1,"")
Place that in E1 and copy down. When A in the same row has "Maruti" it will display the corresponding value from column B. If it does not have Maruti, it will display "" which is essentially a blank for display purposes.
OPTION 2)
INDEX/AGGREGATE Formulas
=IFERROR(INDEX($B$2:$B$15,AGGREGATE(15,6,ROW($A$2:$A$15)/($A$2:$A$15=$D$2)-ROW($A$2)+1,ROW(A2)-1)),"")
Place that in E2 and copy down to E15. Place the name your are looking for in D2.
For more information on formulas used follow the links:
AGGREGATE Formula Excel 2010 and later
IF Formula Excel 2007 and later
IFERROR Formula Excel 2007 and later
INDEX Formula Excel 2010 and later
ROW Formula Excel 2007 and later
I use array formula.
Select E2:E15
then write =IFERROR(INDEX($B$2:$B$15,SMALL(IF(IFERROR(MATCH($A$2:$A$15,$D$2,0),0),ROW(INDIRECT("1:"&ROWS($A$2:$A$15)))),ROW(INDIRECT("1:"&ROWS($A$2:$A$15))))),"")
then press Ctrl+Shift+Enter.
I am working on a personal budget sheet in excel, and it's formatted based on my pay dates, to provide more drilled-down information. I have attached an example of it below for reference.
I would like to put a formula into J2, J3, and J4 which will take the data in cells C9:C26 and H9:H16, match it to the date in cells D2:D4, then subtract the expenses in D9:D26 and I9:I16 from E2, E3, and E4.
As you can see, I have just individually summed the cells; however, I would like a formula to be able to adjust as I change the value in cells C9:C26 and H9:H16.
I have found that I can do it with ONE cell, but not multiple or a range. This is the formula I used, and I cannot find a way to make it apply to the entire range of cells: =IF(C14=D3,E3-D14)
I've also tried: =IF(C9:C25=D3,E3-D9:D25) -- I know this formula doesn't work and why. I cannot figure out how to get column C to correspond with column D.
The Budget Sheet
You just need to use SumIf().
In cell J2, put this formula: =SumIf($C$9:$C$25,$I2,$D$9:$D$25)+SumIf($H$9:$H$25,$I2,$I$9:$I$25) and drag down the three cells.
With that, you can add E2-[formula] to subtract all that from E2. Or of course, just do e2-J2 instead. I think that should do what you're looking for. If it's not quite it, let me know and I can tweak.
If you plan to have more than 1 criteria go with SUMIFS
Yes, with S