Create vba loop to index checkbox and columns - excel

Question

Could someone please point me in the right direction?
View the following code, instead of repetitive lines, I want to loop this to save time...
'show/hide SN# DEFECTIVE
If CheckBox2.Value = True Then Columns("f").EntireColumn.Hidden = False
If CheckBox2.Value = False Then Columns("f").EntireColumn.Hidden = True
'show/hide SN# INSTALLED
If CheckBox3.Value = True Then Columns("g").EntireColumn.Hidden = False
If CheckBox3.Value = False Then Columns("g").EntireColumn.Hidden = True
'show/hide SN# DESCRIPTION
If CheckBox4.Value = True Then Columns("h").EntireColumn.Hidden = False
If CheckBox4.Value = False Then Columns("h").EntireColumn.Hidden = True
'show/hide SN# DESCRIPTION
If CheckBox4.Value = True Then Columns("h").EntireColumn.Hidden = False
If CheckBox4.Value = False Then Columns("h").EntireColumn.Hidden = True
I have the following, which works great...
For i = 2 To 4
chk = Me.Controls("checkbox" & i).Value
MsgBox "checkbox " & i & " " & chk
If chk = False Then
Columns("f").EntireColumn.Hidden = True
Else
Columns("f").EntireColumn.Hidden = False
End If
Next i
However, I also want to index the columns as well, but these are identified as "letters", so how can I also increment an "f" to the next letter "g", and so on...

Answer 1

I wouldn't use loop for this unless you have many more columns to change visibility.
However, what I would do is definitely avoid Ifs and simply use the associate checkboxes' value's opposite to be set as the hidden property value like below. More readable, maintainable and of course shorter.
Columns("f").EntireColumn.Hidden = Not CheckBox2.Value
Columns("g").EntireColumn.Hidden = Not CheckBox3.Value
Columns("h").EntireColumn.Hidden = Not CheckBox4.Value
EDIT: I don't recommend this but to provide you an answer for your question in your way: use Chr function to return letters.
For i = 2 To 4
chk = Me.Controls("checkbox" & i).Value
MsgBox "checkbox " & i & " " & chk
If chk = False Then
Columns(chr(100+i)).EntireColumn.Hidden = True
Else
Columns(chr(100+i)).EntireColumn.Hidden = False
End If
Next i
even shorter using my way:
For i = 2 To 4
Columns(chr(100+i)).EntireColumn.Hidden = Not Me.Controls("checkbox" & i).Value
Next i