excel vba vlookup referencing separate workbook without name - excel

Question

I want a code in one workbook that uses vlookup to reference another workbook without specific identification.
So I have to use vlookup almost every month for about 20 different reports and I want to automate it, but because the names and every other type of information is different, I cannot use names or indexes.
I checked other posts and mainly the answers that I've seen were ones that referenced a name or instead of a name, an index. Because the names are going to be different every time I won't be able to reference to them, it won't be an automated process. I was thinking about looking for some reference like "ActiveWorkbook." The "ActiveWorkbook" reference only targets one workbook however there is one workbook where the data is going to be inputted and one workbook where the source data is.

Answer 1

I believe your problem is that you have started looking for useful pieces of code before learning the basics. This is a very common problem and many are in much worse shape than you. There are many online Excel VBA tutorials. Try a few; find one that matches your learning style and finish it. I prefer books to online tutorials. I visited a large library; reviewed their Excel VBA primers; borrowed the most promised; completed my review at home and bought the one I liked best as a permanent reference.
I need you to pick a folder containing at least three workbooks which I will call workbooks A, B and C. Workbook A must be macro enabled and must have a reference to the Microsoft Runtime Scripting library. At least one workbook should have multiple worksheets. At least one worksheet should have values in row 1.
Copy DemoWbkWsht to a new module in workbook A. In line 49 replace "SheetsMove.xlsm" with the name of workbook C.
Open workbook B. Go to “Run macros” and run macro DemoWbkWsht. That is, run a macro in another workbook. Macro DemoWbkWsht creates a file named “DemoWbkWsht.txt” in the folder. Work down the file and the macro reviewing the output and the statements I used to create that output. I believe I have demonstrated everything you need to know. Come back with questions as necessary but, the more you can understand on your own, the faster you will develop.
The points I particularly want you to notice:
The difference between ActiveWorkbook and ThisWorkbook
Workbooks.Open changes ActiveWorkbook but not ThisWorkbook.
How you can loop through the open workbooks or create an array of
workbook references and loop through them.
How you can loop through every worksheet in a workbook.
How every workbook has an ActiveSheet. This is the worksheet activate when the workbook was last saved. That was why I asked if these workbooks had more than one worksheet. If a workbook has only one worksheet, that worksheet must be the active worksheet.
How you can look at any cell within any worksheet within any open workbook. I have used this ability to list the values in row 1 of every worksheet. These values are column headings in most worksheets. This was my other question: can you identify the target worksheet by its headings? I doubt you need the user’s help, I believe your macro can identify the worksheets you need to access itself.
Good luck
Option Explicit
Sub DemoWbkWsht()
' Needs reference to Microsoft Scripting Runtime library. See Tools->References.
Dim ColCrnt As Long
Dim ColLast As Long
Dim DiagFile As TextStream
Dim Fso As New FileSystemObject
Dim InxWbk As Long
Dim InxWsht As Long
Dim Path As String
Dim WbkA As Workbook
Dim WbkB As Workbook
Dim WbkC As Workbook
Dim WbkCrnt As Variant
' Updating the screen while updating a worksheet is the easiest way of
' ensuring your macro takes FOREVER to run. ALWAYS include this statement
' even if you do not think it is necessary.
Application.ScreenUpdating = False
' Create reference to workbook holding this macro
Set WbkA = ThisWorkbook
' Record path of workbook holding macro.
Path = ThisWorkbook.Path & "\"
' Create the text file to which diagnostic file will be output within
' the folder holding the workbook holding this macro
Set DiagFile = Fso.CreateTextFile(Path & "DemoWbkWsht.txt", True, False)
' List open workbooks. Identify workbook B.
DiagFile.WriteLine "***** Workbooks open when macro started"
For InxWbk = 1 To Workbooks.Count
DiagFile.WriteLine " " & Workbooks(InxWbk).Name
If Workbooks(InxWbk).Name <> WbkA.Name Then
Set WbkB = Workbooks(InxWbk)
End If
Next
' List special workbooks.
DiagFile.WriteLine "***** Special workbooks"
DiagFile.WriteLine " ActiveWorkbook: " & ActiveWorkbook.Name
DiagFile.WriteLine " ThisWorkbook: " & ThisWorkbook.Name
DiagFile.WriteLine " Workbook A: " & WbkA.Name
DiagFile.WriteLine " Workbook B: " & WbkB.Name
Set WbkC = Workbooks.Open(Filename:=Path & "SheetsMove.xlsm")
DiagFile.WriteLine "***** Special workbooks after open of workbook C."
DiagFile.WriteLine " ActiveWorkbook: " & ActiveWorkbook.Name
DiagFile.WriteLine " ThisWorkbook: " & ThisWorkbook.Name
DiagFile.WriteLine " Workbook A: " & WbkA.Name
DiagFile.WriteLine " Workbook B: " & WbkB.Name
DiagFile.WriteLine " Workbook C: " & WbkC.Name
' List worksheets in workbooks A, B and C
For Each WbkCrnt In VBA.Array(WbkA, WbkB, WbkC)
With WbkCrnt
DiagFile.WriteLine "***** Worksheets in workbook """ & .Name & """"
With WbkCrnt
For InxWsht = 1 To .Worksheets.Count
DiagFile.WriteLine PadL(InxWsht, 4) & " " & .Worksheets(InxWsht).Name
Next
DiagFile.WriteLine " ActiveWorksheet: " & .ActiveSheet.Name
End With
End With
Next
' List worksheets in workbooks A, B and C
For Each WbkCrnt In VBA.Array(WbkA, WbkB, WbkC)
With WbkCrnt
DiagFile.WriteLine "***** Worksheets in workbook """ & .Name & """"
For InxWsht = 1 To .Worksheets.Count
DiagFile.WriteLine PadL(InxWsht, 4) & " " & .Worksheets(InxWsht).Name
Next InxWsht
DiagFile.WriteLine " ActiveSheet: " & .ActiveSheet.Name
End With ' WbkCrnt
Next WbkCrnt
' List values from row 1 of worksheets in workbooks A, B and C
For Each WbkCrnt In VBA.Array(WbkA, WbkB, WbkC)
With WbkCrnt
DiagFile.WriteLine "***** Values, if any, from row 1 of each worksheet in workbook """ & .Name & """"
For InxWsht = 1 To .Worksheets.Count
With .Worksheets(InxWsht)
DiagFile.WriteLine PadL(InxWsht, 4) & " Worksheet: " & .Name
ColLast = .Cells(1, .Columns.Count).End(xlToLeft).Column
For ColCrnt = 1 To ColLast
If .Cells(1, ColCrnt).Value <> "" Then
DiagFile.WriteLine Space(5) & ColCode(ColCrnt) & "1=" & .Cells(1, ColCrnt).Value
End If
Next ColCrnt
End With ' .Worksheets(InxWsht)
Next InxWsht
End With ' WbkCrnt
Next WbkCrnt
WbkC.Close SaveChanges:=False
DiagFile.Close
Application.ScreenUpdating = True
End Sub
Function ColCode(ByVal ColNum As Long) As String
Dim PartNum As Long
' 3Feb12 Adapted to handle three character codes.
' 28Oct16 Renamed ColCode to match ColNum.
If ColNum = 0 Then
Debug.Assert False
ColCode = "0"
Else
ColCode = ""
Do While ColNum > 0
PartNum = (ColNum - 1) Mod 26
ColCode = Chr(65 + PartNum) & ColCode
ColNum = (ColNum - PartNum - 1) \ 26
Loop
End If
End Function
Public Function PadL(ByVal Str As String, ByVal PadLen As Long, _
Optional ByVal PadChr As String = " ") As String
' Pad Str with leading PadChr to give a total length of PadLen
' If the length of Str exceeds PadLen, Str will not be truncated
' Sep15 Coded
' 20Dec15 Added code so overlength strings are not truncated
' 10Jun16 Added PadChr so could pad with characters other than space
If Len(Str) >= PadLen Then
' Do not truncate over length strings
PadL = Str
Else
PadL = Right$(String(PadLen, PadChr) & Str, PadLen)
End If
End Function