Excel - efficient way to find data across sheets - excel

Question

I currently have a spreadsheet with two work sheets. The first worksheet is a list of names and addresses, the second is a list with names and addresses plus email addresses (sheet is named "EmailList")
I am trying to add a new column to the first worksheet that will show the email address if the email is in the second sheet by matching the firstname, lastname, house number and street address. Even better would be to show the list on a new sheet with just whole rows that match.
I got the email showing using:
=INDEX(EmailList!P:P, MATCH(A9&B9&C9&E9, EmailList!A:A&EmailList!B:B&EmailList!C:C&EmailList!E:E, 0))
However it is soooooo slow. The first sheet has a 1000 rows, the second sheet 1500.
How can I easily select the rows from the EmailList sheet where the Firstname, Lastname, Number, Street name columns in both sheets match?

Answer 1

The comments by pnuts and Parfait are both excellent suggestions and worth considering.
I'm just wondering if your structural logic is correct. From what you write in your questions, rather than find email address for Sheet1, aren't you actually removing from Sheet2 any addresses that don't exist on Sheet1? If this is the case, then a VBA solution would be quite short and simple. If you created a string key from your names, house number, address cells, you could populate a Collection and simply look up that key in each Sheet2 entry. Some skeleton code for you to develop would be as follows:
Option Explicit
Sub RunMe()
Dim data As Variant
Dim r As Long, c As Long, i As Long
Dim key As String
Dim addrs As Collection
Dim emails As Collection
Dim hit As Boolean
Dim vRow As Variant
Dim output As Variant
'Read addresses from Sheet1 into collection
data = Sheet1.UsedRange.Value2
Set addrs = New Collection
For r = 1 To UBound(data, 1)
key = BuildKey(data, r)
addrs.Add True, key
Next
'Interrogate email list
data = Sheet2.UsedRange.Value2
Set emails = New Collection
On Error Resume Next
For r = 1 To UBound(data, 1)
key = BuildKey(data, r)
hit = False
hit = addrs(key)
If hit Then emails.Add r
Next
On Error GoTo 0
'Write your results to the new sheet
ReDim output(1 To emails.Count, 1 To 5)
i = 1
For Each vRow In emails
For c = 1 To 5
output(i, c) = data(vRow, c)
Next
i = i + 1
Next
Sheet3.Range("A1").Resize(UBound(output, 1), UBound(output, 2)).Value = output
End Sub
Private Function BuildKey(data As Variant, r As Long) As String
Dim c As Long
For c = 1 To 4
BuildKey = BuildKey & CStr(data(r, c)) & "|"
Next
End Function

Answer 2

As mentioned, consider SQL if using Excel for PC. Excel can connect to the Jet/ACE SQL Engine (Window .dll files) to run queries on worksheets as if they were database tables. And yes, you can query the very workbook you run the macro as you will use a read-only instance of last saved file.
Specifically, the query below runs an INNER JOIN between two sheets, MainList and EmailList on the very columns you specified with output to existing worksheet, Results:
Sub RunSQL()
Dim conn As Object, rst As Object
Dim strConnection As String, strSQL As String
Dim i As Integer
Set conn = CreateObject("ADODB.Connection")
Set rst = CreateObject("ADODB.Recordset")
' CONNECTION STRINGS (DRIVER VERSION COMMENTED OUT)
' strConnection = "DRIVER={Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};" _
' & "DBQ=C:\Path\To\Workbook.xlsm;"
strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" _
& "Data Source='C:\Path\To\Workbook.xlsm';" _
& "Extended Properties=""Excel 12.0;HDR=YES;"";"
strSQL = " SELECT t1.*, t2.[EmailAddress]" _
& " FROM [MainList$] t1" _
& " INNER JOIN [EmailList$] t2" _
& " ON t1.FirstName = t2.FirstName" _
& " AND t1.LastName = t2.LastName" _
& " AND t1.HouseNumber = t2.HouseNumber" _
& " AND t1.StreeAddress = t2.StreetAddress;"
' OPEN CONNECTION
conn.Open strConnection
rst.Open strSQL, conn
' COLUMN HEADERS
For i = 1 To rst.Fields.Count - 1
Worksheets("Results").Cells(1, i) = rst.Fields(i).Name
Next i
' DATA ROWS
Worksheets("Results").Range("A2").CopyFromRecordset rst
rst.Close: conn.Close
End Sub

Answer 3

I know this is a dev site, but if you want a super-easy to do this with no code whatsoever, you can use PowerPivot, which is a free AddIn.
You can get the AddIn from here.
https://support.office.com/en-us/article/Power-Pivot-Add-in-a9c2c6e2-cc49-4976-a7d7-40896795d045
Again, it's just another option for you. I like Parfait's suggestion! Very elegant, sir!!