Get last day in month in AppleScript and holidays in current month - excel

Question

I am writing an AppleScript which generates an MS Excel spreadsheet every month. I need to know how many days are in the current month, then go trough all months and decide if a given day is a weekday or a holiday.
I suppose I would save holidays (from this web http://kalendar365.cz/statni-svatky/2016 as table and access them locally) for this.
My question is:
How do I get the last day in a month?
How do I efficiently loop trough all days in the current month and decide if it is Sunday, Saturday or a day specified somewhere else (for example, in a text file of xlsx spreadsheet)?

Answer 1

pbell's answer is promising, but the GetLastDay function doesn't work correctly for months that have fewer than 31 days; here's a function that fixes that:
# Returns the number of days in the month that the given date falls in.
# Example:
# my GetNumberOfDaysInMonth(current date)
on GetNumberOfDaysInMonth(aDate)
local aDateCopy
copy aDate to aDateCopy
set day of aDateCopy to 1
if month of aDateCopy is December then
set year of aDateCopy to ((year of aDateCopy) + 1)
set month of aDateCopy to 1
else
set month of aDateCopy to ((month of aDateCopy) + 1)
end if
return day of (aDateCopy - 1 * days)
end GetNumberOfDaysInMonth
The approach is based on setting the date to the 1st of the month, then incrementing the month (possibly rolling over into the next year), and subtracting 1 day, which works correctly with all dates, even in leap years.

Answer 2

How about a simple no-function-needed method?
set currdate to the current date
set nextmonth to currdate + (30 * days)
set {year:y, month:m, day:d, time:t} to nextmonth
set ms to m as string --month as string
set ys to y as string --year as string
set firstday to date (m & " 1," & y as string) --midnight at the first day of next month
set lastday to (firstday - 1) --minus one second
return lastday -- last day of the this month at 11:59 PM
As for weekends and holidays in Excel, doesn't Excel provide its own functions for that, as dirk-reichel mentioned?
However, if you want to use AppleScript to filter out these days using a pre-specified list of holidays, maybe this example will help. It loops through October through December of 2022, with USA holidays Halloween, Thanksgiving and Christmas Day specified. Note that Christmas Day happens to land on a Sunday in 2022.
set weekend to {"Saturday", "Sunday"}
set holidays to {date "October 31, 2022", date "November 24, 2022", date "December 25, 2022"}
set workdays to {}
set my_date to (date "Saturday, October 1, 2022 at 12:00:00 AM")
repeat
set dy to the weekday of my_date
set mydy to dy as string
if weekend does not contain mydy and holidays does not contain my_date then
set workdays to workdays & my_date
end if
set my_date to my_date + (1 * days)
if my_date contains (date "January 1, 2023") then --specify an end date for your loop
exit repeat
end if
end repeat
return workdays

Answer 3

The script below contains the 2 routines you're looking for : GetlastDay and isWorkingDay :
set myDate to current date -- just for example !
set N to GetlastDay(myDate)
log N --> number of days in month of myDate
set A to IsWorkingday(myDate)
log A --> true if Monday to Friday, false if Saturday/Sunday
on GetlastDay(LDate) -- return last day of month of LDate
copy LDate to L -- to not change LDate
set L's day to 32 -- = first day of next month
set L to L - (1 * days) -- last day of month
return day of L
end GetlastDay
on IsWorkingday(LDate) -- true if date is not Saturday or Sunday
set SD to weekday of LDate
return (SD is not in {Saturday, Sunday})
end IsWorkingday