Excel VBA Nested For loop issue - excel

Question

I have a large dataset with 60 sheets from which I need to extract three values per sheet individually. These values are to be summarized in one sheet so I can have an overview of the data.
I took an internet crash course in VBA to try and write a macro to avoid having to do this manually. My idea (that I was able to translate to code) was to copy the three cells per sheet to the rows of a 2D array, so I would end up with a [60x3] matrix that could be copied to a newly created sheet 'Means'. (I understand that this is very inefficient however it's the best I could come up with for now.)
The code runs but produces undesirable results: the matrix only consists out of a triplet of values from the final sheet. What I actually need from my macro is that it copies three values from sheet1 and pastes them to MeanTable(1,:), then copies three values from sheet2 and pastes them to MeanTable(2,:) and so on. I am convinced this is happening because my first nested loop is rubbish so I have been trying different loops and adding loops (and web searching of course) but so far I haven't been able to solve it.
Sub copy_to_one_sheet() 'copy sample means from each sheet to Means
Application.ScreenUpdating = False
Dim ws As Worksheet
Dim NumSheets As Integer
Dim NumSamples As Integer
Dim MeanTable() As Long 'store sample means in this 2D array, its size defined by number of sheets and samples per sheet
NumSheets = Application.Sheets.Count 'count number of sheets
NumSamples = 3 'number of samples per sheet (hardcoded for now)
ReDim MeanTable(NumSheets, 1 To NumSamples) 'MeanTable will be filled with sample means
'============================================
'= copy sample means per sheet to MeanTable =
'============================================
For i = 1 To UBound(MeanTable, 1) 'copy sample means from fixed columns per sheet to individual rows of Table array
For Each ws In ThisWorkbook.Worksheets 'go through sheets
MeanTable(i, 1) = ws.Cells(Rows.Count, 3).End(xlUp).Offset(-3, 0).Value
MeanTable(i, 2) = ws.Cells(Rows.Count, 10).End(xlUp).Offset(-3, 0).Value
MeanTable(i, 3) = ws.Cells(Rows.Count, 17).End(xlUp).Offset(-3, 0).Value
Next ws
Next i
'=============================================
'= create Sheet("Means") and paste MeanTable =
'=============================================
With ThisWorkbook
Set Dst = .Sheets.Add(After:=.Sheets(.Sheets.Count)) 'create new worksheet
Dst.Name = "Means" 'worksheet name
With Sheets("Means")
For k = 1 To UBound(MeanTable, 1)
For l = 1 To NumSamples
Cells(k, l).Value = MeanTable(k, l) 'paste Table variable with sample means to new worksheet ("Means")
Next l
Next k
End With
End With
End Sub
My question is: how can I make my loops cycle through each sheet in the workbook and copy a triplet of values to the corresponding rows of MeanTable, before moving on to the next sheet?
Any help would be greatly appreciated!

Answer 1

For i = 1 To UBound(MeanTable, 1) needed to be replaced with a counter i = i + 1`. Use Range.Resize to fill a range from an array.
Sub copy_to_one_sheet() 'copy sample means from each sheet to Means
Application.ScreenUpdating = False
Dim ws As Worksheet
Dim NumSheets As Integer
Dim NumSamples As Integer
Dim MeanTable() As Long 'store sample means in this 2D array, its size defined by number of sheets and samples per sheet
NumSheets = Application.Sheets.Count 'count number of sheets
NumSamples = 3 'number of samples per sheet (hardcoded for now)
ReDim MeanTable(1 To NumSheets, 1 To NumSamples) 'MeanTable will be filled with sample means
For Each ws In ThisWorkbook.Worksheets 'go through sheets
i = i + 1
MeanTable(i, 1) = ws.Cells(Rows.Count, 3).End(xlUp).Offset(-3, 0).Value
MeanTable(i, 2) = ws.Cells(Rows.Count, 10).End(xlUp).Offset(-3, 0).Value
MeanTable(i, 3) = ws.Cells(Rows.Count, 17).End(xlUp).Offset(-3, 0).Value
Next ws
With ThisWorkbook
Set Dst = .Sheets.Add(After:=.Sheets(.Sheets.Count)) 'create new worksheet
Dst.Name = "Means" 'worksheet name
With Sheets("Means")
.Range("A1").Resize(UBound(MeanTable, 1), UBound(MeanTable, 2)).Value = MeanTable
End With
End With
End Sub