Excel Date formatting with hash marks for some reason - excel

Question

The Problem
I've got a VBA program that exports data from one Excel file into a CSV. When it comes across a date, it formats it like #2016-06-14#. I'm assuming the hash marks (or octothorpe or pound sign or hashtag) are meant to indicate that the field is a date field. But, when I'm importing the CSV back into a different Workbook, the date will not come in no matter how I format the field. It still contains the # characters.
The Question
How can I get the date column to import as a YMD format date?
Appendix
Here's some code I'm using to export and import, for reference.
Export
Sub WriteCSV(writeRange As Range, fileName As String)
Dim myFile As String, rng As Range, cellValue As Variant, i As Integer, j As Integer
myFile = ActiveWorkbook.Path & "\Results\" & fileName & ".csv"
Debug.Print myFile
Open myFile For Output As #1
For i = 1 To writeRange.Rows.Count
For j = 1 To writeRange.Columns.Count
cellValue = writeRange.Cells(i, j).value
If j = writeRange.Columns.Count Then
Write #1, cellValue
Else
Write #1, cellValue,
End If
Next
Next
Close #1
End Sub
Import
Sub ReadCSV(targetCell As Range, filePath As String)
With ActiveSheet.QueryTables.Add(Connection:= _
"TEXT;" & filePath, Destination:=targetCell)
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.TextFilePromptOnRefresh = False
.TextFilePlatform = 437
.TextFileStartRow = 2
.TextFileParseType = xlDelimited
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileConsecutiveDelimiter = False
.TextFileTabDelimiter = False
.TextFileSemicolonDelimiter = False
.TextFileCommaDelimiter = True
.TextFileSpaceDelimiter = False
.TextFileColumnDataTypes = Array(1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1)
.TextFileTrailingMinusNumbers = True
.Refresh BackgroundQuery:=False
.Delete
End With
End Sub

Answer 1

Try outputing .text instead of .value.
Change this:
cellValue = writeRange.Cells(i, j).value
to this:
cellValue = writeRange.Cells(i, j).Text

Answer 2

Discard those #.
When I manually Save as a file as CSV, Excel does NOT put those # around the dates. Instead it writes the dates as they are defined in my regional settings (that is - for me - dd/mm/yyyy).
And when importing back, the recorder used array(...4...) for the date column, and it was imported correctly.
Anyway CSV really sucks if your are working in an international environment since it behaves differently according the the local machine settings. Being poorly defined, it's the last format I would use.