Please find attached screenshot of my Excel doubt.
As in the screenshot, I want to update the 3rd and 4th row values in the 2nd row, leaving those dates without any value.
In the screenshot it is shown that in the question part 3rd row dates with 5/17/1997 5/18/1997 does not have any values. So want to leave those cell blank and update the rest with the date and values in the 3rd and 4th row, leaving those dates without value for the rest of the cells. Kindly help me with any functions or formulas for doing this.
First step: copy paste Row 3 to Row 10.
Formula in AUE11:
= IFERROR( If(Match(AUE$10, $AUE$4:$AUV$4, 0) > 0, AUE$10, "") , "")
Formula in AUE12:
= If(AUE$11 <> "", Index($AUE$5:$AUV$5, 1, Match(AUE$10, $AUE$4:$AUV$4, 0)), "")
Remember to format Row 10 and 11 as Dates, otherwise you might get numbers as a result (e.g. 35562 instead of 5/12/1997). Also, adjust the range (AUE:AUV) to your actual range.
Related
I have multiple rows of students on a spreadsheet and their grades across the top as column headers. Not all students do every subject I have listed so therefore some columns will be blank. I am trying to use these grades as a range and have the populated cells appear all next to each other at the end of the spreadsheet. I will hen need the subject header to come with the non-blank cells data.
See the screenshot below to understand what data needs to go where:
I found a kind of answer on stack but its totally the wrong way round to how I have to work (see the image below). So, please help me flip this around so names would go down column A and subjects along the first row. (This is in a Google Sheet).
Lee
Here is a mock up of what I am trying to achieve, all data will likely be on one student row, but I have organised like this for the screenshot.
Based on your annotated screenshot, here's how to get from the top table to the bottom table.
Put your Subject 1, etc. headings in manually.
Put ={G13:G16} into G20 to copy your student names.
In H20 use =INDEX(FILTER($H$12:$O$12, $H13:$O13 <> ""), 1, 1) to grab the first heading in $H$12:$O$12 that is over a non-blank cell in $H13:$O13.
In the above formula, FILTER() grabs all the headings over non-blank cells in the range, while INDEX() is used to grab the first result.
Repeat the formula for H21:H23 (letting Sheets update the references that aren't fixed with a $ prefix.)
In I20 use =INDEX(FILTER($H13:$O13, $H13:$O13 <> ""), 1, 1) to grab the first non-blank value in $H13:$O13.
Repeat the formula for I20:I23.
Moving right, just copy the formulas, but update the values for INDEX() but increase the column argument by one. eg. J20 would contain =INDEX(FILTER($H$12:$O$12, $H13:$O13 <> ""), 1, 2) and K20 would contain =INDEX(FILTER($H13:$O13, $H13:$O13 <> ""), 1, 2).
This should get you well on your way.
Happy spreadsheeting!
This might be easy for many but I need to solve an issue which is following;
I have the following formula which finds the empty row after D4.
=MATCH(TRUE;D4:D1048576="";0)+3
After this I want to be able to find the empty row from another defined cell, say D10.
How can I do this?
Try this as an array formula - Ctrl+Shift+Enter:
=MIN(IF(D4:D100="",ROW(D4:D100)))
It works from D4 to D100, providing the first empty value.
If you're looking to use same formula to match next cell then use
For blanks after D4
=MATCH(TRUE,INDEX(ISBLANK(D4:D1048576),0),0)
For blanks after D10
=MATCH(TRUE,INDEX(ISBLANK(D10:D1048576),0),0)
To find the A1th blank cell, you can use the following formula:
=AGGREGATE(15,6,ROW(D:D)/--ISBLANK(D:D),A1)
How it works
AGGREGATE(15,6,..) is like SMALL(..), but skips any error values.
ROW(..) provides the row number of the cell provided
ISBLANK(..) is TRUE for blank cells or FALSE for non-blank cells
-- converts TRUE to 1 and FALSE to 0. This means that ROW(D:D)/--ISBLANK(D:D) will be either the Row Number (for blank cells) or a #Div0! error (which AGGREGATE will skip)
This produces a list of row numbers for all the blank cells, and you then use the AGGREGATE function to get the kth item in that list.
Taking it a step further
So, you want the 1st item larger than a specific row. We change the last argument in AGGREGATE to 1, and swap change our "Error out" code from ISBLANK(D:D) to AND(ISBLANK(D:D), ROW(D:D)>A1), to get the first blank row after the row number stored in A1:
=AGGREGATE(15, 6, ROW(D:D)/--AND(ISBLANK(D:D), ROW(D:D)>A1), 1)
I'm entering datas in A column of a table. According to the datas, I making sums from the yellow cell (actually this yellow cell is the high value of the A column). So all 10 cells, there is a sum until the end of datas.
I'm looking for automatically report the seven first grey cells (the sums)to another table. The problem is, according to the datas, high value is not at the same place so the sums are not to the same place too.
How can I do ?
Thank you for your help
MY ERROR :
And the message when I press ctrl maj enter in same time :
You might use this array formula in your report.
=INDEX($F:$F,SMALL(ROW($F$4:$F$117)+(100*(F$4:$F$117="")), ROW(F1)))&""
Bear in mind that, as an array formula, it must be confirmed with Control+Shift+Enter. Enter the formula in the row where you have Somme = 1, then copy down to 6. Note that Row(F1) is a counter. You have a similar counter (1 to 6) in F124:F130. Therefore you can replace ROW(F1) with $F124 (if that is where the "1" is) to make it easier to understand, perhaps.
The formula retrieves the value of the 1st, 2nd, 3rd etc non-blank cell in the range F4:F117. If those cells contain a formula they will be considered "blank" if their result equals "".
BTW, if you don't always have 113 results to evaluate you might consider giving a name to the range E4:E117. For example, if you name that range as "Results" then =SUM(Results) would be the same as =SUM($E$4:$E$117), but as you insert or delete rows within the named range the formula doesn't need to be amended. Use of a named range would simplify understanding your existing formula. You could do the same with column F.
Finally I find a solution to report the values from F to another table. As values positions are dependant of the MAX raw in E (every 10 cells) I make this formula :
For the first : INDEX(E4:F117;EQUIV(GRANDE.VALEUR($E$4:$E$117;1);$E$4:$E$117;0)+10;2)
For the second :
INDEX(E4:F117;EQUIV(GRANDE.VALEUR($E$4:$E$117;1);$E$4:$E$117;0)+20;2)
Etc...
I have dates in columns U,X,AA,AD,AG and AJ and Names in V,Y,AB,AE,AH and AK. I have the following formula to select the latest updates as they are updated. Columns U and V will be filled first and then columns X and Y are updated at a later date. I need both the date and name column to be filled before the cells in another worksheet are updated.
This is the formula I am using, which is very long, but I can't work out how to make it shorter. For the date I am swapping the columns for the date column (U,X,AA,AD,AG and AJ)in the second half of the formula
=CHOOSE(1+COUNT('Training Schedule'!U42,'Training Schedule'!V42,'Training Schedule'!X42,'Training Schedule'!Y42,'Training Schedule'!AA42,'Training Schedule'!AB42,'Training Schedule'!AD42,'Training Schedule'!AE42,'Training Schedule'!AG42,'Training Schedule'!AH42,'Training Schedule'!AJ42,'Training Schedule'!AK42),"",'Training Schedule'!V42,'Training Schedule'!Y42,'Training Schedule'!AB42,'Training Schedule'!AE42,'Training Schedule'!AH42,'Training Schedule'!AK42)
This formula works but if no entry is made in the name column a 0 (zero) is copied into the name column. How do I get it to show a blank cell? If I add a name but no date nothing is copied across. I have another formula to count the date and name formula to copy into another worksheet, but it is counting the 0 as if the cell if filled. I have made so many versions of the file I'm working with and have mistakenly deleted my original which used to work with no 0 and I can't remember how I did it!
If you do not have numbers in W42, Z42, AC42, AF42 & AI42 I would suggest the following alternate formula.
=IFERROR(IF(LEN(INDEX(V42:AK42, MATCH(1E+99, U42:AJ42))), INDEX(V42:AK42, MATCH(1E+99, U42:AJ42)), ""), "")
The above intermediate cells can contain text, but this method looks for the last number (aka date) in that range of cells so the intermediate cells cannot contain numbers or dates if the last date in U42, X42, AA42, AD42, AG42 & AJ42 is to be correctly determined.
Was using this formula SheetName!CellAddress
I need to import Data that is available on other 2 sheets namely (sheet2 and sheet3) into sheet 1 in a way such that
the row values will be alternate i.e one value from sheet 2 and other value from sheet 3 respectively
Have tried like this
=Sheet2!C2
=Sheet3!D2
when i dragged for other values i was get only values in the even cell like(c4,d4,c6,d6)
If i change the for formula to
=Sheet2!C1
=Sheet3!D1
i was get only values in the even cell like(c3,d3,c5,d5)
But what i need is continous cells in row( c1,d1,c2,d2,c3,d3...)
So what formula i need to use for getting this result
I am still not 100% clear on what the question is asking, so let me know if the below answer doesn't work for you.
It sounds like what you're looking for can be accomplished with OFFSET and clever use of IF statement.
Suppose your formulas will be in column A, starting in A2. Then enter the following formula into A2 (line split added for readability; remove it):
= IF(MOD(COUNTA(A$1:A1),2)=0, OFFSET(Sheet2!$C$1, COUNTA(A$1:A1) / 2, 0),
OFFSET(Sheet3!$D$1, COUNTA(A$1:A1) / 2, 0))
Then drag the formula down.
What it does:
MOD(COUNTA(A$1:A1),2)=0 - checks whether we're in odd row or even row.
COUNTA(A$1:A1)/ 2 - takes half of the number of non-empty cells immediately above the current cell.
OFFSET(Sheet2!$C$1, COUNTA(A$1:A1) / 2, 0) - takes the cell which is COUNTA(A$1:A1)/ 2 cells below Sheet2!$C$1.
Here's a fairly basic method:
Enter the first two formulas as Text - you can either do this by formatting the cell number as text or preceding the formula by an apostrophe.
Select cells and fill down to get:
=Sheet2!C2
=Sheet3!D2
=Sheet2!C3
=Sheet3!D3
=Sheet2!C4
=Sheet3!D4
...
Select the column and choose Data|Text to Columns|Finish to change text to values.