Find text in column A e.g. ID number "10502" - excel

Question

I currently have a list of employees which have completed training within the whole company. I am trying to create a macro to find the employees with my department via their employee number and copy them over to Worksheet 2.
Employee Number is in column A. This employee may have multiple entries under their ID. I want to copy all information on that row from Column A to Column N. I than want to paste those entries into Sheet2.
We have 187 Employees within our department. Any help with finishing this would be greatly appreciated.
Sub ()
Worksheets("Sheet1").Activate
Range("A1").Activate
' Find the first ID Number
Cells.Find(What:="10503", After:=ActiveCell, SearchDirection:=xlPrevious).Select
' copy and paste Text2
ActiveCell.Offset(0, 0).Copy
Worksheets("Sheet2").Select
Range("A65000").End(xlUp).Offset(1, 0).Select
ActiveCell.PasteSpecial (xlPasteAll)
Worksheets("Sheet1").Activate
End Sub

Answer 1

Try this:
Sub FindandCopyRow()
Dim targetSh As Worksheet
Set targetSh = ThisWorkbook.Worksheets("Sheet2")
Dim i As Long
For i = 1 To Cells(Rows.Count, "A").End(xlUp).Row
If Cells(i, 1).Value = "10503" Then '--->change ID here as required
Rows(i).EntireRow.Copy Destination:=targetSh.Range("A" & targetSh.Cells(Rows.Count, "A").End(xlUp).Row + 1)
End If
Next i
End Sub

Answer 2

I just added some data to #Mrig's answer.
One being the use of Application.InputBox which prompts the user to insert the employee number instead of the user editing the code every time.
I also just Sheet referencing for the various part of the For loop, always good to reference the sheets you are in to avoid consufion for the next user and then Application itself.
Sub FindandCopyRow()
Dim DataSh As Worksheet
Set DataSh = ThisWorkbook.Worksheets("Sheet1")
Dim targetSh As Worksheet
Set targetSh = ThisWorkbook.Worksheets("Sheet2")
Dim EmployeeNumber As Long
'This allows you to enter an employee number and not have to edit the code every time
EmployeeNumber = Application.InputBox(Prompt:="Please Enter Employee Number:", Type:=1)
'Try use descriptive naming for variables.....always
Dim DataShRowRef As Long
'Remember to always reference the sheet you are in when counting and copying etc
For DataShRowRef = 1 To DataSh.Cells(DataSh.Rows.Count, "A").End(xlUp).Row
If DataSh.Cells(DataShRowRef, 1).Value = EmployeeNumber Then
DataSh.Rows(DataShRowRef).EntireRow.Copy Destination:=targetSh.Range("A" & targetSh.Cells(targetSh.Rows.Count, "A").End(xlUp).Row + 1)
End If
Next DataShRowRef
End Sub