Excel recursion - find last in a sequence - excel

Question

Using Excel 2010 & have a list of parts, some of which can have their part number changed. If a part has been changed, it will be in one worksheet (Column A), and its new value (column B). There is also a date time stamp on the change.
In my list of all part numbers, I need to
Check to see if the part has been changed, and
Follow it through each of it's changes until I find the last one.
The "last one" can mean EITHER
The value in Column B (newVal) is not in Column A(oldval) OR
If it refers back to itself (a correction), in which case the newest Date Time stamp is the determining factor.
Corrections to the list are entered by adding a row which would redirect it to the previous (correct) version. An example:
oldVal A changes to newVal B 2016-04-08 11:39:04.765
oldVal B changes to newVal C 2016-04-08 12:21:39.801
(we find out the B--> C change is incorrect)
oldVal C changes to newVal B 2016-04-08 13:44.07.913
I know that a vLookup won't do this. I think that SUMPRODUCT may solve the first part, but I'm not sure how to do the recursion (or if it's possible) for the time part of it.
Any thoughts, ideas, solutions would be appreciated.
EDIT
Additional Info -
The desired output
What I want to show in the NewPartNo column is the last value in the chain for that part number. If the Part number went from A --> B --> C --> D, I would want to see D in the NewPartNo column for the PartNo in column A.
You have a 1960-1 that has a newVal of 25-1960. The problem is that the 25-1960 then has a newVal of OBB1960. How many levels of recursive misplaced vals are there?
That's the issue - in some places a part may be (originally) named any one of the ones in column A. As far as how many levels - I don't know. Possibly 5-10, maybe? I don't know exactly.
EDIT 2
#TMDean's solution mostly worked, except for when I had data like below.
If starting with A001, it maps to B001. B001's newest (most recent date) mapping is to C001. C001's mapping (to itself) has the same date-time stamp as the other one, so A001 should map to C001.
In stepping through the function, it will find the first one (A001 -> B001), but throws an error when it tries to find the second one (B001 -> C001).
In the above, the correct result of the lookup should be A001 -> C001.

Answer 1

Here are two UDFs¹ to retrieve the recursive newVal and it's associated date.
Option Explicit
Function newestVal(lu As Range, rng As Range)
Dim val As Variant
Static app As New Application
'truncate the rng down to the used range
Set rng = Intersect(rng, rng.Parent.UsedRange)
val = lu.Value2
With rng
If IsError(app.Match(lu.Value2, .Columns(1), 0)) Then
val = app.Index(.Columns(2), app.Match(val, .Columns(2), 0), 1)
Else
Do While Not IsError(app.Match(val, .Columns(1), 0))
val = app.Index(.Columns(2), app.Match(val, .Columns(1), 0), 1)
Loop
End If
End With
newestVal = val
End Function
Function latestValDate(lu As Range, rng As Range)
Dim d As Long, val As Variant, dbl As Double
Static app As New Application
'truncate the rng down to the used range
Set rng = Intersect(rng, rng.Parent.UsedRange)
val = lu.Value2
With rng
If IsError(app.Match(lu.Value2, .Columns(1), 0)) Then
val = app.Index(.Columns(2), app.Match(val, .Columns(2), 0), 1)
Else
Do While Not IsError(app.Match(val, .Columns(1), 0))
val = app.Index(.Columns(2), app.Match(val, .Columns(1), 0), 1)
Loop
End If
For d = app.Match(val, .Columns(2), 0) To rng.Rows.Count
If .Cells(d, 2).Value2 = val Then
If .Cells(d, 3).Value2 > dbl Then
dbl = .Cells(d, 3).Value2
End If
End If
Next d
End With
latestValDate = dbl
End Function
In F2:G2 as,
=newestVal(E2,A:C )
=latestValDate(E2,A:C )
    
¹ A User Defined Function (aka UDF) is placed into a standard module code sheet. Tap Alt+F11 and when the VBE opens, immediately use the pull-down menus to Insert ► Module (Alt+I,M). Paste the function code into the new module code sheet titled something like Book1 - Module1 (Code). Tap Alt+Q to return to your worksheet(s).

Answer 2

This is all psuedo code but it should get you ion the right direction. Give me a couple of hours and I can do it for you, but it might be fun for you to try and figure it out.
If Selection Offset Column + 1 <> vbNullString then
newvalue = Selection Offset Column + 1.value
for i = 1 to 100
If newvalue Offset Column + 1 = vbNullString then
Display (i)a,b,c
Exit For
ElseIf newvalue Offset Column + 1 <> vbNullString then
newvalue = newvalue Offset Column + 1.value
Next i

Answer 3

Inspired by Jeeped's solution, I wondered if it could be more general purpose and wrote a UDF implementation of a recursive version of VLOOKUP.
This function works just like VLOOKUP except it will follow the chain of lookup values until it gets to the end of the table, as described in the problem.
Option Explicit
Function VLOOKUPR(LookupValue As Variant, _
TableArray As Range, _
ColIndexNum As Long, _
RangeLookup As Boolean)
Dim LookupIndex
Set TableArray = Intersect(TableArray, TableArray.Parent.UsedRange)
VLOOKUPR = CVErr(xlErrNA)
Do
LookupIndex = Application.Match(LookupValue, TableArray.Columns(1), _
IIf(RangeLookup, 1, 0))
If IsError(LookupIndex) Then Exit Do
VLOOKUPR = TableArray(LookupIndex, ColIndexNum)
If LookupValue <> TableArray(LookupIndex, 1) Then Exit Do
LookupValue = TableArray(LookupIndex, ColIndexNum)
Set TableArray = Intersect(TableArray, TableArray.Offset(LookupIndex))
Loop Until TableArray Is Nothing
End Function
Since I wanted it to be general purpose, I didn't include the requirement that it return the lookup value instead of #N/A if it exists in column B. You can include this logic in the cell formula you use to call VLOOKUPR. =IFERROR(VLOOKUPR($E2,$A$2:$A$100,2,FALSE),VLOOKUP($E2,$B$2:$B$100,1,FALSE))