I have difficulty in converting the timestamp recorded in excel. The format is in scientific, I would like to convert to date format in excel.
Scientific = 2.02207E+13 (in number format 20220715030838)
I expect the result will be 15-Jul-2022 03:08
Thanks
Use below formula to convert date/time value.
=--TEXTJOIN("/",TRUE,MID(A1&"",{1,5,7},{4,2,2}))+(--TEXTJOIN(":",TRUE,MID(A1&"",{9,11,13},{2,2,2})))
Then use cell format to display results as desired format. Or can use TEXT() function like-
=TEXT(--TEXTJOIN("/",TRUE,MID(A1&"",{1,5,7},{4,2,2}))+(--TEXTJOIN(":",TRUE,MID(A1&"",{9,11,13},{2,2,2}))),"dd-mmm-yyyy hh:mm")
My answer is here, make sure that singe digit date should come with 0 as highlighted in the pic. Either you can customise the format or use Text function.
If you want seconds as well then use Right(A2,2) function in Second argument in the Time function. Hope it clears.
=TEXT(INT(DATE(LEFT(A2,4),MID(A2,5,2),MID(A2,7,2)))+TIME(MID(A2,9,2),MID(A2,11,2),),"dd-mmm-yyy hh:mm")
=INT(DATE(LEFT(A2,4),MID(A2,5,2),MID(A2,7,2)))+TIME(MID(A2,9,2),MID(A2,11,2),) #customise the format.
How can I create a custom time format?
I'm using a Excel sheet to track my work hours. And I add up the work hours for each day and get a week total. But it seems it cant display above 24:00. unless I change the format to hh:mm:ss.
I don't want the extra 2 digits at the end but the only other option is hh:mm.#
I want it to be hh:mm but display more than 24 hrs (like 36:50).
I also don't understand the "custom" option can someone help?
Use:
[hh]:mm
As your custom format
I am trying to convert a datetime string such as 2015-11-01-02.02.38.444000 to Datetime format in Excel. I have tried solutions provided in previous questions, but this particular format was not covered. I am looking to have both date and time in the same cell. Please assist.
It depends how consistent the strings are, but for this particular one you could try
=VALUE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"-"," ",3),".",":",1),".",":",1))
then use custom formatting to show it as a datetime value with milliseconds
dd/mm/yyyy hh:mm:ss.000
(you may have to change this for your locale).
BTW to make the TIMEVALUE formula in your comment work you would have to change the first two decimal points to colons.
So my problem is i copy paste an agenda in excel with time in a format like 9h20. I want to convert it into 9:20 but i can't find the way to do it.
Just changing format doesn't work.
Thanks in advance for your help.
Use:
=TIMEVALUE(SUBSTITUTE(A1,"h",":"))
and format as Time
I have a column of date-time numbers, "DD/MM/YY HH:MM:SS". At this moment, I want to remove "SS" from it and left "DD/MM/YY HH:MM". I tried DATE and TIME function separately but only one part left, DATE:"DD/MM/YY" and TIME:"HH:MM", also, I tried CONCATENATE function but it doesn't work, so could anyone do me a favour? Thanks in advance.
If you want to completely remove the seconds from the data.
Try: =1*TEXT(C2,"dd/mm/yyyy hh:mm")
Multiplying the text result by 1 converts the text back to a number.
Select the cell(s) to be modified and tap Ctrl+1. Go to the Number tab and chose Custom from the list down the left. Supply the following for the Type:
dd/mm/yy hh:mm ◄ EN-US
pp/kk/vv tt:mm ◄ FI-FI
Click OK and you should be set.
You can try LEFT. Assuming I understand your question and you have DD/MM/YY HH:MM:SS in one cell, you can use =LEFT(cell,14)
Try this formula:
Round(CELL * 60 * 24 , 0)/60/24
Try =TEXT(A1,"DD/MM/YY HH:MM")
I have a column showing dates "27/01/2015 18:43:00"
I changed them to show as Number "42031.78"
I then used Data/Text to columns and used the period or full stop as the delimiter.
This gave me two columns "42031.00" and "7798611111.00"
I deleted the second column and changed the original column back to short date format. "27/01/2015"
No more hours and seconds!
to remove the seconds just do =INT("cell number"*1440)/1440