Fortran program compiled with fopenmp shows only one thread - multithreading

Question

I have a big code in Fortran, it has a commercial license so that I cannot
post the code. It contains several modules each of them with several subroutines. I compiled that code with the -fopenmp flag (I used the flag
for all files in the program).
In one subroutine I placed the code
!$OMP PARALLEL
nthreads=OMP_GET_NUM_THREADS()
write(6,*) 'threads', nthreads
!$OMP END PARALLEL
Initially, the program complains about the unrecognized OMP_GET_NUM_THREADS data type. I saw some post on this forum and there
it was suggested to use use omp_lib to load run-time libraries . After
adding this line to the subroutine, the program ran but it printed
threads 1
as if only one thread were used even when I set
export OMP_NUM_THREADS=10
My questions are, should I use use omp_lib in each subroutine? or maybe
only on the "main" program?
As I said before, this subroutine (where I wrote the omp directives) is
inside a module.

Answer 1

You need to have OMP_Get_num_threads() declared in the scope of the subroutine where it is used. This might happen with a use statement within that subroutine, or, since you are using modules, in the header of the module. In the snippet pasted below, I did both.
Note, that the function call to OMP_Get_num_threads() needs to be embedded in a parallel section (as you did in the code snippet), otherwise the result is always 1.
Since the modules have no access to the scope of the main program, useing the module there is not sufficient (but the compiler will tell you that when you are linking the binary).
module testMod
use omp_lib, only: OMP_Get_num_threads
implicit none
contains
subroutine printThreads()
use omp_lib, only: OMP_Get_num_threads
implicit none
! This will always print "1"
print *,OMP_Get_num_threads()
! This will print the actual number of threads
!$omp parallel
print *,OMP_Get_num_threads()
!$omp end parallel
end subroutine
end module
program test
use testMod, only: printThreads
implicit none
call printThreads()
end program
with the following results:
OMP_NUM_THREADS=2 ./a.out
1
2
2
OMP_NUM_THREADS=4 ./a.out
1
4
4
4
4