How to check if elements of macro are in another macro - string

Question

I have a simple-seeming problem, but in practice it seems to be more involved. In python, for example, it seems like it would be much more straightforward. But I would really like to learn how to do this in Stata.
Say that I have a big dataset. I have several string variables, S1, S2, and S3. I get a subset of S1 based on some criteria. Let's say that this gets me (after sorting and only the data of interest are displayed):
S1
1 A
2 B
3 C
4 D
5 E
Based on different criteria, I get, for S2:
S2
1 B
2 B
3 C
4 F
For S3:
S3
1 B
2 Long string
What I am interested in doing is to get a list of all of the distinct values across S1, S2, and S3. One way I have thought about doing this is:
Save all desired values of S1 into a macro, M1. I didn't figure out how one is able to do this.
Save all desired values of S2 into a macro, M2.
Check if the values of M2 are in M1. Do not add the values of M2 to M1 that are already in M1, but do add the values of M2 to M1 that are not already there. It seems like this post is similar to how to do this step. (Why is there a : in front of list?)
Repeat step 3, except for S3/M3 instead of S2/M2.
This would produce the macro M1 with values:
A B C D E F Long String
Note that I do not need this to be in a macro. If it could be in a matrix or some other way, that would work as well. The important part is to get the information.

Answer 1

Several ways to do this.
Many assumptions made in this example (many things are not clear in your post):
clear
set more off
input ///
str15(s1 s2 s3)
a "b" "b"
b "b" "long string"
c "c" ""
d "f" ""
e "" ""
end
list
stack s*, into(news) clear
bysort news : keep if _n == 1
drop _stack
list
If you want to work your way through, using macros, then help macrolists and help levelsof can aid:
clear
set more off
input ///
str15(s1 s2 s3)
a "b" "b"
b "b" "long string"
c "c" ""
d "f" ""
e "" ""
end
list
local uvalues
foreach var of varlist _all {
levelsof `var', local(loc`var')
local uvalues : list uvalues | loc`var'
}
display `"`uvalues'"'
Saying more about how your variables are organized (e.g. one or several files), whether you care or not to destroy the original data set, the treatment of missings, etc. can probably get you an ad hoc answer.