VBA Loop not working correctly - excel

Question

I am new to writing VBA and not sure to to complete this loop. I am reading down a column and identifying the cell color. If the cell color is correct then i preform the action. The problem is that action pastes that info into cell N7. That is where my loop gets messed up because i need it to go the cell A9 next. Can some one explain what the next step would be. I know that need to put that cell A8 in a loop and increase by 1 each time but not sure how to do that.
Range("A8").Select
Do
If ActiveCell.Interior.Color = RGB(79, 129, 189) Then
ActiveCell.Offset(1, 0).Select
Selection.End(xlDown).Select
ActiveCell.Offset(-1, 0).Select
Range(Selection, Selection.End(xlUp).Offset(1, 0)).Select
Selection.Copy
Range("N7").Select
ActiveSheet.Paste
ElseIf ActiveCell.Select = "BREAK" Then
Exit Sub
Else
ActiveCell.Offset(1, 0).Select
End If
Loop
End Sub

Answer 1

Edit: updated script below to copy data per additional comments
.Select and .Activate are common sources of run-time errors and can likely be avoided in this case. Though I'm not really clear on the action you're trying to take when you identify the color in column A, you could use the following heavily-commented script to accomplish the "loop-and-check-for-BREAK" action.
Option Explicit
Sub ProcessColumnA()
Dim Counter As Long
Dim MySheet As Worksheet
Dim Cell As Range, DestCell As Range
'set references up-front
Counter = 8
Set MySheet = ThisWorkbook.ActiveSheet
Set Cell = MySheet.Cells(Counter, 1)
Set DestCell = MySheet.Cells(7, 14)
'loop on column A until we find "BREAK" or
'counter is greater than 10K, whichever comes first
Do Until Cell.Value = "BREAK" Or Counter > 10000
'check color and take action if necessary
If Cell.Interior.Color = RGB(79, 129, 189) Then
'do the copy work here
Cell.Copy Destination:=DestCell
'increment the destination cell
Set DestCell = DestCell.Offset(1, 0)
End If
'increment the counter variable and set the next cell
Counter = Counter + 1
Set Cell = MySheet.Cells(Counter, 1)
Loop
'send user a message regarding the results
If Counter > 10000 Then
MsgBox ("Whoa you hit 10K cells before finding 'BREAK'...")
Else
MsgBox ("Processing complete!")
End If
End Sub