Backing up a document in the background - c#-4.0

Question

I know how to create an vs2013 addin for word which automatically saves a document in the background:
this.Application.Documents[#"C:\Test\NewDocument.docx"].Save();
The problem with this is, that if the user is saving the document to:
C:\MyDocument.docx and doesn't realise that the location has changed in the background to C:\Test\NewDocument.docx, they might get confused.
So my question is, is it possible to somehow create a backup of the document in the background in a different location? So the addin automatically keeps saving to C:\Test\NewDocument.docx, but when the user clicks the builtin save function in Word, it saves to where the user thinks it should be saving too.
Is this possible?

Answer 1

Let's first make clear what you are doing
Your
this.Application.Documents[#"C:\Test\NewDocument.docx"].Save();
is not any magic that saves file in the background. It just saves the document into a specific a path (C:\Test) with a specific name {NewDocument.docx). So you simply save document, nothing else.
If you want to make a copy of an existing document and you don't want to force user to save it, you have two options
auto save feature in Word (I don't know how to control that via code)
make a copy of existing file that must be at least once saved
Let's talk about #2, you can easily copy a file from one location to another but the file must be closed. So there is an another approach a functional example is bellow (I don't like accessing Globals directly but for this example is OK)
Public Class ThisAddIn
Dim _myTimer As System.Windows.Forms.Timer
Private Sub ThisAddIn_Startup() Handles Me.Startup
_myTimer = New System.Windows.Forms.Timer
With _myTimer
.Interval = 30000 ' 30 sec
AddHandler .Tick, AddressOf TimerEventOcured
.Start()
End With
End Sub
Private Sub ThisAddIn_Shutdown() Handles Me.Shutdown
If _myTimer IsNot Nothing Then _myTimer.Stop()
End Sub
Private Sub TimerEventOcured(ByVal sender As Object, ByVal e As EventArgs)
CopyFile()
End Sub
Private Sub CopyFile()
Const DEST_PATH As String = "c:\"
Const FILE_NAME As String = "BackUp.docx"
Try
Dim currentDoc As Word.Document = Globals.ThisAddIn.Application.ActiveDocument
' was it saved at least once, the full path then contains extension, e.g. dotx
If Not currentDoc.FullName.Contains(".") Then Return
' makes copy of the current document with UNSAVED changes and save it to specified location
Dim backUpCopy As Word.Document = currentDoc.Application.Documents.Add(currentDoc.FullName)
Dim tmpFileNAme As String = System.IO.Path.GetTempFileName.Replace(".tmp", ".dotx")
backUpCopy.SaveAs2(FileName:=tmpFileNAme, AddToRecentFiles:=False)
System.IO.File.Copy(sourceFileName:=tmpFileNAme, _
destFileName:=Path.Combine(DEST_PATH, FILE_NAME), _
overwrite:=True)
' remove the temp files
backUpCopy.Close(SaveChanges:=False)
System.IO.File.Delete(tmpFileNAme)
System.IO.File.Delete(tmpFileNAme.Replace(".dotx", ".tmp"))
Catch ex As Exception
System.Windows.Forms.MessageBox.Show(String.Format("hey, an error here{0} {1}", vbNewLine, ex.Message))
End Try
End Sub
End Class