Get and sort all views in a database - lotus-notes

Question

I have some code that gets a list of all views&folders in a database. The problem is everything is very poorly organized. The list of views shows as almost random, although I assume there is some order...
Is there a way to take the list of all the views that show on the dialog prompt, and then sort the list alphabetically?
Sub Initialize
Dim s As New NotesSession
Dim w As New NotesUIWorkspace
Dim dbSource As NotesDatabase, dbDest As NotesDatabase
Dim source As NotesView, dest As NotesView
Dim vc As NotesViewEntryCollection
Dim docDest As NotesDocument
Dim ve As NotesViewEntry
Dim folders() As String
Dim i As Integer
Dim ret, rez
Set dbSource = s.CurrentDatabase
ForAll v In dbSource.Views
If v.IsFolder Then
i = i + 1
ReDim Preserve folders( i - 1 ) As String
folders( i - 1 ) = v.Name
End If
End ForAll
ret = w.Prompt( PROMPT_OKCANCELLISTMULT, "Folder selection", "Select one or more folders to move.", folders(0), folders )
If IsEmpty( ret ) Then
MessageBox "User canceled", , "Folder not selected"
Exit Sub
Else
rez = w.Prompt( 13, "Database selection", "Choose the database to move the folder to" )
ForAll f In ret
Set source = dbSource.GetView( f )
Set vc = source.AllEntries
Set dbDest = s.GetDatabase( rez(0), rez(1), False )
Call dbDest.EnableFolder( f )
Set ve = vc.GetFirstEntry
Do Until ve Is Nothing
Set docDest = ve.Document.CopyToDatabase( dbDest )
Call docDest.PutInFolder( f )
Set ve = vc.GetNextEntry( ve )
Loop
Call vc.RemoveAllFromFolder( f )
Call source.Remove
End ForAll
End If
End Sub

Answer 1

You can add this subroutine to sort the folders array before you include it in your prompt method.
Just call ShellSort(folders) before the line with w.Prompt();
Sub ShellSort( ar( ) As String )
Dim Lower As Integer
Dim Upper As Integer
Dim botMax As Integer
Dim i As Integer
Dim k As Integer
Dim h As Integer
Dim v As String
Lower% = Lbound( ar$( ) )
Upper% = Ubound( ar$( ) )
h% = 1
Do
h% = (3*h%) + 1
Loop Until h% > Upper%-Lower%+1
Do
h% = h% \ 3
botMax% = Lower% + h% - 1
For i% = botMax% + 1 To Upper%
v$ = ar$( i% )
k% = i%
While ar$( k% - h% ) > v$
ar$( k% ) = ar$( k% - h% )
k% = k% - h%
If (k% <= botMax%) Then Goto wOut
Wend
wOut:
If (k% <> i%) Then ar$(k%) = v$
Next
Loop Until h% = 1
End Sub
(source: http://www.dominoexperts.com/articles/Very-fast-sorting-algorithm)

Answer 2

You can use #Sort in a Evaluate call to get the folder names sorted.
Dim foldersList As String
Dim folders As Variant
...
ForAll v In dbSource.Views
If v.IsFolder Then
foldersList = foldersList + |:"| + Replace(Replace(v.Name, |\|, |\\|), |"|, |\"|) + |"|
End If
End ForAll
If foldersList <> "" then
folders = Evaluate(|#Sort(| + StrRight(foldersList, ":") + |)|)
...
The code above works this way:
First collect all folder names in a string as a formula list like
"xyz":"abc":"mno":"def"
Make sure that quotation marks in folder names are replaced by \" and backslashes for subfolders are replaced by \\.
Second evaluate a formula with #Sort("xyz":"abc":"mno":"def").
The result is a sorted variant string array you can use in your w.Prompt(..., ..., folders(0), folders ) like before.
The benefit of this solution is a very short code and it is fast too.

Answer 3

If you use a list instead of an array then the values will be automatically placed in a sorted order. eg.
Dim folders List As Boolean
ForAll v In dbSource.Views
If (v.IsFolder) Then folders(v.Name) = True
End ForAll