Non-linear secondary xlabel - gnuplot

Question

I want to plot a function/dataset, where the secondary x-axis is a function of the primary x-axis, e.g. 1/x (non-linear). The reason for this is that they are both meaningful parameters. I can set the range correctly by using my "function", however, values in between are different. The following figure shows what is wrong:
What is wrong here, is that the x2-axis get linearly ticced (is that proper English?). Example: the tic opposite to 1.6 is now 0.7, but should be 0.625 for this case.
Script to reproduce this:
xmin=1.
xmax=2.
set xlabel "x"
set xrange [xmin:xmax]
set x2tics
set x2label "1/x"
set x2range [1/xmin:1/xmax]
plot x
Is a fancy general way to change the axis-scaling/labeling, other than logarithmic?

Answer 1

You can use a do for approach to loop through a manual label setting (set x2tics add). Here's the edited minimal example you provided (see comments in the script for explanations):
xmin=1.
xmax=2.
inc=0.2 # for more control over the tics
f(x)=1./x # Function that defines the secondary axis
fplot(x)=x # Function that is plot
set xlabel "x"
set xrange [xmin:xmax]
set xtics xmin,inc,xmax # specify the actual location for xtics, too
ntics = (xmax-xmin)/inc + 1 # calculate the number of tics
inc2 = (f(xmin)-f(xmax))/(ntics-1) # calculate increment for x2tics
fmin=f(xmin); fmax=f(xmax)
set x2tics fmin,-1*inc2,fmax # set x2tics, labels will be rewritten
# the following loops through the number of tics
# the <set x2tics add ("x2" x2)> command will be repeated
# use arithmetic to calculate the values and the locations
# you need <sprintf> to convert the tic label number into a string
do for [i=1:ntics+1] {
xtic=xmin+(i-1)*inc
x2ticpos=f(xmin)-(i-1)*inc2
set x2tics add (sprintf("%.3g",f(xtic)) x2ticpos)
}
set x2range [f(xmin):f(xmax)]
set yrange[fplot(xmin):fplot(xmax)] # you should also specify the yrange, to avoid surprises
plot fplot(x)
And the plot you'll get is this: