I have three sheets, sheet1, sheet2, and sheet3.
Sheet 1 have column like : Project, employee name, hours worked, date
Sheet 2 have Column like : employee name, rate/hour
So the common between two sheets are employee name.
Sheet 1 will be updating every day, so that sheet will not have define range.
$ spent will be calculated on = Sheet1! hours worked * Sheet2 rate/hour (Here common in both sheet is employee name)
Total $ spent on each project, that i achieved, but i need to know how to calculate $ spent on last 30 days.
You can use IF to remove older values from your sum. Something like:
=IF(NOW()-Sheet1!Date <= 30, Sheet1!HoursWorked*Sheet2!Rate,0)
Create a new column in Sheet 1 titled "Cost". Put following formula in E2 and copy down.
=IF(D2-TODAY()>30,0,C2*INDEX(SHEET2RATECOLUMN,MATCH(b2,SHEET2NAMECOLUMN,0)))
Create a new pivot table on Sheet 3 using sheet 1 as the input. Put the employees on the rows, and sum "Cost" in the data section of the table.
Assumes Sheet 1 Column D is date, Column B is employee, and Column C is hours.
Sheet 1
Project Employee Hours Date
AA Ken 2.0 14-Feb
BB Ken 1.0 01-Jan
AA Rob 1.5 15-Feb
BB Ken 7.0 01-Mar
Sheet 2
Employee Rate
Ken 50.00
Rob 20.00
Sheet 3
Project Ken Rob Total
AA <B2>
BB
Total
in B2 enter the following formula
=SUMIFS(Sheet1!$C:$C,Sheet1!$B:$B,B$1,Sheet1!$A:$A,$A2,Sheet1!$D:$D,">"&TODAY()-30)*INDEX(Sheet2!$B:$B,MATCH(B$1,Sheet2!$A:$A,0))
Copy formula to all projects rows, and employee columns. Put Sum equation into "total" columns and rows.
Related
I am having two sheets Sheet1 & Sheet2, Sheet1 having four columns like EMP No, Project Number, Month & Working Days.
In the sheet2 I have same four column but some employee will be worked in two projects for that month, For example: If Emp No, project number & month matches, then 4th column value for that employee should be populated. And I am doing this by referring the cells in both the sheets.
Both sheets having the same order as mentioned in the below.
Column A = Emp No,
Column B = Project Number
Column C = Month
Column D = Working Days
=SUMIFS('Sheet2',$D$2:$D$10000,$C$2:$C$10000,"="&M2,$B$2:$B$10000,"="&C2,$A$2:$A$10000,A2)
I gather your aggregation happens in Sheet2 so the formula should be:
=SUMIFS(Sheet1!D:D,Sheet1!A:A,Sheet2!A1,Sheet1!B:B,Sheet2!B1,Sheet1!C:C,Sheet2!C1)
If your aggregations happens in Sheet1 just go with this one:
=SUMIFS(Sheet2!D:D,Sheet2!A:A,Sheet1!A1,Sheet2!B:B,Sheet1!B1,Sheet2!C:C,Sheet1!C1)
If I've understood correctly, Sheet2 can contain multiple lines for employees per project per month? So, for example, EMP No 1 could be listed for Project 1, in the month of January 5 times, with working days each time equalling 1, and Project 2, int he month of January 2 times, with working days each time equalling 1.
Your Sheet1 worksheet, intends to list all employees, projects and months uniquely in order to total the days worked on each project each month? Based on the example, EMP No 1 would have the following displayed:
What I would suggest, is providing you have the unique list in Sheet1 already set up, enter the following formula into cell D2 (Working Days) and then copy down. I have assumed 100 entries on Sheet2, so you will need to amend the Sheet2! ranges in the formula to suit your data.
=SUMIFS(Sheet2!$D$2:$D$101,Sheet2!$A$2:$A$101,Sheet1!$A2,Sheet2!$B$2:$B$101,Sheet1!$B2,Sheet2!$C$2:$C$101,Sheet1!$C2)
I have a problem creating a pivot table/chart with between date function.
I would like to know the total count of projects that are active between two dates. A Chart with on the x-axis week 1 - week 52 is what i'm trying to create.
Example Chart
20
10
5
0
week 1 week 2 week 3 .....
My columns:
Project ID | START WEEK NUMBER| END WEEK NUMBER
What have I already done?
Adding helper columns 1 till 52 with the following function:
=IF(AH$1=MEDIAN($AB10;$AD10);1;IF(AH$1=$AB10;1;IF(AH$1=$AD10;1;"")))
This will show a 1 when the column week header is equal or between date start week and end week. But with this I am still not able to create a chart with the weeks on the x-axis and the total count of that week.
Make a new sheet and in Column A put your weeks 1-52 down. In column B use this formula:
=COUNTIFS(Sheet6!$B$2:$B$18,"<="&A2,Sheet6!$C$2:$C$18,">="&A2)
Sheet6! Needs to be replaced with the name of your Sheet, e.g. Projects!
Column B range needs to be the entire range of your start week
Column C range needs to be the entire range of your end week
B and C dimensions need to match.
If you need to use a pivot table, try rearranging your source data as shown:
I have excel file having sheets month wise. more than 1000 lines items with different prices in each month. i want to make one sheet of each items segregating prices by months.
for Example,
if (column A1) item is matching to (sheet1 Column A) than put the (Sheet1 column C Value) in (column C).
Item # Jan Price Feb Price Mar Price
Item 1
Item 2
Item 3
Item 4
Item 5
Item 6
please help.
Assuming 1 is in B2 the other sheets are called Sheet2, Sheet3 etc then in C2 and copied down to suit and all the formulae copied across (presumably eleven column) to suit:
=VLOOKUP($B2,INDIRECT("Sheet"&COLUMN()-2&"!A:C"),3,0)
In my workbook, I have a 4 spreadsheets - Data, Amy, Betty, Connie. Data has the following columns:
Column A Column B Column C Column D
Row 3 Employee Total tasks last 30 days. Total tasks last 7 days. Date/Time Last task Assigned
Row 4 Amy
Row 5 Betty
Row 6 Connie
In A1 - worker with oldest task Date/Time Assigned. Cell B1 contains the answer to cell A1 by providing the employees name.
I enter the data in the individual workers spreadsheets (Amy, Betty, Connie) and my Data worksheet provides the summary. On my data worksheet, I have formulas that count the number of tasks within the last 7 days and last 30 days by using the date/time assigned column (Column E)in the individual worksheets. Currently, if someone is out of the office, on their individual worksheet, I enter OUT in the task column (Column B) and the date/time that they will return in the date/time assigned column (Column E)so it will skip them for B1 on my Data worksheet. I need a formula that would not count the date/time assigned if they were OUT as a task, when calculating in columns B and C in the data worksheet.
Here is the formula that I have currently for Column B (total tasks last 30 days)
{=COUNTIF(INDIRECT("'"&A4&"'!"&"E1:E1000"),">="&(NOW()-30))}
The formula that I have for cell B1 is:
{=INDEX(A4:A14,MATCH(MIN(E4:E14),E4:E14,0))}
Any help would greatly be appreciated.
I figured it out:
=COUNTIFS(Amy!E2:E1000,">="&(NOW()-30),Amy!A2:A1000,"<>out")
Like suggested in the comments, the COUNTIFS formula is what you want to use. Information about its usage can be found here.
Adding the condition for excluding the "OUT" values would make the formula look like this:
=COUNTIFS(INDIRECT(""&A4&"!"&"E1:E1000"),">="&(NOW()-30),INDIRECT(""&A4&"!"&"B1:B1000"),"<>OUT")
So I have column A (cat) and column B (Amt) on lots of separate works sheets.
Cat | Amt
1 | 3.4
4 | 7.4
2 | 8.4
4 | 9.4
What I need is to have a grand total for each category type across all the worksheets.
So a total for category 4, a total for category 2 etc.
This is more suitable for VBA solution, however if you know how many unique "Cat" you have, then it can be done without VBA.
For each sheet on C column add SUMIF formula, this will give sum for each group.
C2=SUMIF($A:$A,A2,$B:$B) - copy it down for each row.
On Sheet11 Column A is your unique "Cat" list. Columns B1 to K1, name them as Sheet1, Sheet2, ...Sheet10.
B2=IFERROR(VLOOKUP($A2,INDIRECT(B$1&"!$A:$C"),3,FALSE),0) - copy it for each row, column.
Column L will be GrandTotal.
G2=SUM(B2:K2) - copy it for each row.