Splitting two words in excel - excel

Question

Spliiting Words together in a pair like (Head LM) from other word in a cell in Excel
Name Role
John Dowe (Head LM); Moniq Jamese (Lead JK); Larrye Stuarte (Front TR) John Dowe Head LM
I need to be able to split [Head LM] from the rest of the text without the parentesis, just Head LM. I tried several options like:
=TRIM(RIGHT(SUBSTITUTE(S3," ",REPT(" ",100)),300))
=RIGHT(S3, LEN(S3)-FIND(" ", S3,1)-5) =>resule is : (Lead PM); J
In both instances the text isn't clean from the () and other words.

Answer 1

if A1 contains:-
John Dowe (Head LM); Moniq Jamese (Lead JK); Larrye Stuarte (Front TR)
This:-
=LEFT(MID(A1,FIND("(",A1)+1,LEN(A1)),FIND(")",MID(A1,FIND("(",A1)+1,LEN(A1)))-1)
returns:-
Head LM
For clarification:-
MID(A1,FIND("(",A1)+1,LEN(A1)) finds the part of A1 that starts after the first (
FIND(")",MID(A1,FIND("(",A1)+1,LEN(A1))) works out the number of characters to the second )
LEFT({...first snippet...},{...second snippet...}-1) trims off the second )
Update to handle all names/titles
A1 your example text
B1 =LEFT(A1,FIND(";",A1))
C1 =LEFT(B1,FIND(" (",B1)-1)
D1 =MID(B1,FIND("(",B1)+1,FIND(")",B1)-(FIND("(",B1)+1))
E1 =MID(A1,LEN(B1)+2,FIND(";",A1)+3)
F1 =LEFT(E1,FIND(" (",E1)-1)
G1 =MID(E1,FIND("(",E1)+1,FIND(")",E1)-(FIND("(",E1)+1))
H1 =MID(A1,LEN(B1)+2+LEN(E1)+1,LEN(A1))
I1 =LEFT(H1,FIND(" (",H1)-1)
J1 =MID(H1,FIND("(",H1)+1,FIND(")",H1)-(FIND("(",H1)+1))
B1 pulls the first name block (up to the first semi-colon)
E1 pulls the second name block (up to the second semi-colon)
H1 pulls the third name block
C1, F1, I1 pull the name from their respective block
D1,G1,J1 pull the title from their respective block
Any columns that are not required can be hidden - leaving just the required ones visible. Breaking out the three blocks into B1, E1 and H1 make the formulae in the other cells simpler - but could be avoided, by substituting (for example) the formula in B1 wherever B1 appears in the other formulae (though this, obviously, makes those formulae even more complex). This would then remove the need to hide any unwanted columns - as you would only calculate the values you require.

Answer 2

This assumes that you want to get ALL of the words in parentheses, not just the first occurrence (this was not really clear in your question, so I assumed you were interested in all of them). To do this, you'll need to split that cell using Text-To-Columns or something of that nature, so that your formula only has to deal with one name/title at a time. Then copy/transpose it so that each name/title is in its own row.
That done, you can use a formula like:
=SUBSTITUTE(SUBSTITUTE(RIGHT(A1,LEN(A1)-FIND("(",A1,1)+1),"(",""),")","")
Here is a picture:
If you don't need ALL of the titles in parentheses, then you could obtain only the first instance without doing any Text-to-Columns/additional steps/etc. as per #dav1dsm1th's answer.

Answer 3

Split this into a number of smaller problems so it makes sense.
To find the beginning of the word, first find the open paren
=FIND( "(", A1 )
To find the end of the word, find the close paren that follows your open paren
=FIND( ")", A1, FIND( "(", A1) )
So with these worked out, you can find your word. It starts 1 character after the open paren and goes for the length between the two minus that 1 character.
= MID( A1, FIND( "(", A1 ) + 1 , ( FIND( ")", A1, FIND( "(", A1) ) - FIND( "(", A1 ) ) - 1 )