Vim E139: Workaround - vim

Question

I have a MoveToFile Function that appends selected text to a file and then deletes it.
command! -nargs=* -complete=file -range=% -bang -bar MoveToFile
\ :<line1>,<line2>call MoveToFile(<q-args>, <bang>0)
function! MoveToFile(fname, overwrite) range
let r = a:firstline . ',' . a:lastline
exe r 'w>>' . ' !'[a:overwrite] . fnameescape(a:fname)
exe r 'd'
endfunction
A problem arises when the file I'm trying to append to is already open in Vim. How can I get around this?

Answer 1

You can catch the E139: File is loaded in another buffer. If you really need
to handle this corner case, yank the contents, open the existing buffer via :buffer {fname}, and paste them:
try
exe r 'w>>' . ' !'[a:overwrite] . fnameescape(a:fname)
catch /^Vim\%((\a\+)\)\=:E139/
exe r 'yank'
exe 'sbuffer' fnameescape(a:fname)
$put
hide
endtry

Answer 2

You can use writefile() (note that this will overwrite file hence must first get current contents hence is unusable for large ones):
function MoveToFile(fname, _) range abort
let lines=readfile(a:fname, 'b')
if !empty(lines) && empty(lines[-1])
call remove(lines, -1)
endif
let [first, last]=((a:firstline>a:lastline)?([a:lastline, a:firstline]):([a:firstline, a:lastline]))
let lines+=getline(first, last)+['']
call writefile(lines, a:fname, 'b')
execute first.','.last.'delete _'
endfunction
Note: to get the same encoding as with :w>> you need to replace line
let lines+=getline(first, last)+['']
with
let lines+=map(getline(first, last), 'iconv(v:val, &enc, &fenc)')+['']
. To also respect 'dos' file format:
let lines+=map(getline(first, last), 'iconv(v:val, &enc, &fenc)'.((&ff is# 'dos')?('."\r"'):('')))+[(&ff is# 'dos')?("\r"):('')]
(respecting 'mac' file format is trickier).