How do I protect my Indy socket writes with a critical section? - multithreading

Question

cs.Acquire;
try
AContext.Connection.Socket.Write(packet);
finally
cs.Release;
end;
or
EnterCriticalSection(cs);
AContext.Connection.Socket.Write(packet);
LeaveCriticalSection(cs);
I trying to send my packet to server in thread, but I have 20 threads which is also sending data to same connection socket. I'm try use Critical Section or Mutex, and they both don't work, I receive the garbage when all threads are sending.
it's all about my previous question
Packet looks like this:
LengthData
0000000010HelloWorld
Server receive data:
ReadBytes(10);
len := (Then remove zeros from begining);
ReadBytes(len); // data.
Sometimes I receive garbage in ReadBytes(10), it's a mix of Length+Data something like: "10Hellowor"
If I send data to server using only one thread, all works fine, every time.
If many threads is sending, all goes wrong.

Answer 1

CS/mutex locks work just fine when used properly. Make sure that your threads are locking the same CS/mutex instance, not separate instances. Since you are sending the data from the server side, I would suggest using the OnConnect event to create a per-connection CS and store it in the TIdContext.Data property, and the OnDisconnect event to free it, eg:
procedure TForm1.IdTCPServer1Connect(AContext: TIdContext);
begin
AContext.Data := TCriticalSection.Create;
end;
procedure TForm1.IdTCPServer1Disconnect(AContext: TIdContext);
begin
AContext.Data.Free;
AContext.Data := nil;
end;
Then you can do this when needed:
TCriticalSection(AContext.Data).Acquire;
try
AContext.Connection.Socket.Write(packet);
finally
TCriticalSection(AContext.Data).Release;
end;
A slightly more encapsulated usage would be to derive a new class from TIdServerContext instead, eg:
type
TMyContext = class(TIdServerContext)
private
CS: TCriticalSection;
public
constructor Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil); override;
destructor Destroy; override;
procedure SendPacket(const AData: TIdBytes); // or whatever parameters you need
end;
constructor TMyContext.Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil);
begin
inherited;
CS := TCriticalSection.Create;
end;
destructor TMyContext.Destroy;
begin
CS.Free;
inherited;
end;
procedure TMyContext.SendPacket(const AData: TIdBytes);
begin
CS.Acquire;
try
Connection.IOHandler.Write(AData);
finally
CS.Release;
end;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
IdTCPServer1.ContextClass := TMyContext;
end;
Then you can do this when needed:
TMyContext(AContext).SendPacket(packet);