Group rows by value over more than one sheet - excel

Question

ive been looking into adding a groupBy function on a couple of sheets however i want to reference 5 sheets. In total i have about 7 but two of the worksheets have the common values in different columns (the five sheets have common variables in column B however two have the same variables in column G) otherwise i would have used ActiveSheet.
I've attached Chris Neilsen's example
Chris Neilsen's Group By Function
Sub demo()
Dim r As Range
Dim v As Variant
Dim i As Long, j As Long
With ActiveSheet
On Error Resume Next
' expand all groups on sheet
.Outline.ShowLevels RowLevels:=8
' remove any existing groups
.Rows.Ungroup
On Error GoTo 0
Set r = .Range("B1", .Cells(.Rows.Count, 2).End(xlUp))
End With
With r
'identify common groups in column B
j = 1
v = .Cells(j, 1).Value
For i = 2 To .Rows.Count
If v <> .Cells(i, 1) Then
' Colum B changed, create group
v = .Cells(i, 1)
If i > j + 1 Then
.Cells(j + 1, 1).Resize(i - j - 1, 1).Rows.Group
End If
j = i
v = .Cells(j, 1).Value
End If
Next
' create last group
If i > j + 1 Then
.Cells(j + 1, 1).Resize(i - j - 1, 1).Rows.Group
End If
' collapse all groups
.Parent.Outline.ShowLevels RowLevels:=1
End With
End Sub
I have tried the below code to link the sheets in the above example however it is out of range
With Worksheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet5")).Select

Answer 1

This can be easily done by adding a parameter to the sub code from Chris Neilsen:
Sub demo(ByRef ws As Worksheet)
Dim r As Range
Dim v As Variant
Dim i As Long, j As Long
With ws
On Error Resume Next
' expand all groups on sheet
.Outline.ShowLevels RowLevels:=8
' remove any existing groups
.Rows.Ungroup
On Error GoTo 0
Set r = .Range("B1", .Cells(.Rows.Count, 2).End(xlUp))
End With
With r
'identify common groups in column B
j = 1
v = .Cells(j, 1).Value
For i = 2 To .Rows.Count
If v <> .Cells(i, 1) Then
' Colum B changed, create group
v = .Cells(i, 1)
If i > j + 1 Then
.Cells(j + 1, 1).Resize(i - j - 1, 1).Rows.Group
End If
j = i
v = .Cells(j, 1).Value
End If
Next
' create last group
If i > j + 1 Then
.Cells(j + 1, 1).Resize(i - j - 1, 1).Rows.Group
End If
' collapse all groups
.Parent.Outline.ShowLevels RowLevels:=1
End With
End Sub
Now call that routine with any worksheet, or in a loop:
Sub Test()
Dim ws As Worksheet
For Each ws In ThisWorkbook.Sheets
demo ws
Next ws
End Sub
PS: I do suggest changing the name of demo to something more appropriate, such as GroupDataOnSheet.