Understanding How Many Configurations of Product are Sold - excel

Question

Each configuration is set-up as a different Part number that makes up one complete device. We want to find out how many of each full configuration we have sold to tell the highest selling combinations. The configuration numbers relate to an option of the product for instance 12345-W means wireless.
We need to find out how many of each string of configurations we have to count them. This has a few columns that will help to find the configuration. You can look at the line number and the sales number to ensure that they are in the same grouping on the sales order. For instance one whole config that makes up a finished product will have line number 1 for all parts associated with the finished product, going down the sales order numerically. We can use this in combination with the sales order to come up with the Configuration String. Then we can look at the config column and part column to differentiate the base config from the options. The "C" in the Config column tells us it's the base model, the "X" tells us it's an option.
With this information we need to create the configuration string shown as a manual example in blueish/purple column, photo linked below. Once we have the string it's just counting the "C" config option only to avoid double counting then we can make a Pivot Table to tell how many duplicates of the same option there are and filter for C only. These are multiple different products, and multiple different configurations of different products.
Here is the Set-up:
Data example: the Blue column is an example manually of what is needed
Some thoughts I had were an If, then statement, Concatenation IF, or a Macro. But nothing has worked out so far. Any advice would be greatly appreciated!

Answer 1

To be able to do that efficient you need to ensure that the data is sorted in the following way:
by Sales
by linenum
by Config
by Part
It needs to be sorted by all 4 columns at once and in this order or you might end up with messed up data!
It is also assumed that the option numbers are always prefixed with the corresponding base number plus a dash.
Then we read the columns we need into arrays (for faster processing). We loop through that data line by line. When we find a C in config we rember that row number (for comparison of the X options and for writing the output). We move on with the next row and check if it is an option and if it belongs to the rembered base config. If so we append the option part no to the base config.
In the end we write the array data back to the cells.
Option Explicit
Public Sub GetFullConfigFromOptions()
Dim ws As Worksheet ' define your sheet here
Set ws = ThisWorkbook.Worksheets("Sheet1")
Dim LastRow As Long
LastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
' read data columns into array
Dim ArrSalesNo() As Variant 'define Sales column
ArrSalesNo = ws.Range("A1").Resize(RowSize:=LastRow).Value
Dim ArrConfig() As Variant 'define Config column
ArrConfig = ws.Range("B1").Resize(RowSize:=LastRow).Value
Dim ArrPartNo() As Variant 'define Part column
ArrPartNo = ws.Range("C1").Resize(RowSize:=LastRow).Value
Dim ArrLineNo() As Variant 'define Linenum column
ArrLineNo = ws.Range("E1").Resize(RowSize:=LastRow).Value
' create output array
Dim ArrOut() As Variant 'define String column
ArrOut = ws.Range("D1").Resize(RowSize:=LastRow).Value
Dim CurrentConfigRow As Long
Dim iRow As Long
For iRow = 2 To LastRow
If ArrConfig(iRow, 1) = "C" Then
' is config line …
CurrentConfigRow = iRow ' remember line number for output
If iRow = LastRow Then
' base without options (in last row)
ArrOut(CurrentConfigRow, 1) = ArrPartNo(CurrentConfigRow, 1) ' write base part number to output (without dash)
ElseIf Not ArrSalesNo(CurrentConfigRow + 1, 1) = ArrSalesNo(CurrentConfigRow, 1) Or _
Not ArrLineNo(CurrentConfigRow + 1, 1) = ArrLineNo(CurrentConfigRow, 1) Or _
Not ArrConfig(CurrentConfigRow + 1, 1) = "X" Then
' base without options
ArrOut(CurrentConfigRow, 1) = ArrPartNo(CurrentConfigRow, 1) ' write base part number to output (without dash)
Else
' base with options
ArrOut(CurrentConfigRow, 1) = ArrPartNo(CurrentConfigRow, 1) & "-" ' write base part number to output (including dash)
End If
Else
' check if it is an option line of the remebered config line
If ArrSalesNo(iRow, 1) = ArrSalesNo(CurrentConfigRow, 1) And _
ArrLineNo(iRow, 1) = ArrLineNo(CurrentConfigRow, 1) And _
ArrConfig(iRow, 1) = "X" Then
' is option line (so append to output)
ArrOut(CurrentConfigRow, 1) = ArrOut(CurrentConfigRow, 1) & Mid$(ArrPartNo(iRow, 1), Len(ArrPartNo(CurrentConfigRow, 1)) + 2)
End If
End If
Next iRow
' write ouput to cells
ws.Range("D1").Resize(RowSize:=LastRow).Value = ArrOut
End Sub
The output will look like