I'm looking for a bit of help on something. I've a total displayed for each month (with different years of course), for example 39.99€ for Dec-19. In November 2019, I'd like to see this amount in my orange cell. In December 2019 I'd like to see the amount for January 2020, etc...
Many thanks in advance for your help.
Edouard
Use Index Match:
=INDEX(I:I,MATCH(EDATE(TODAY(),1),A:A))
Related
Hi All and thank you in advance for any help.
I have several projects that start and finish in different years and want to spread the contract value proportionately over each year. For example a project might start on 1 July 2020 and end 30 June 2022 with a value of $20 million. So how would I automatically populate a value for each of these years, this example would have $5m in 2020, $10m in 2021 and $5m in 2022. The issue is I have about 100 projects that have started since 2013 and some are not due to finish until 2024 so some degree of auomation will help me. I have set up a spread sheet as follows
Excel spreadsheet
Hope this makes sense and any help will be much appreciated.
Good Day,
Try the following formula in the "Contract Days per Year":
=MAX(0,MIN(DATE(E$1,12,31),$B3)-MAX(DATE(E$1,1,1),$A3)+1)
Then you will just multiply the result in the "Contract Value by Year"
for 2019 year, copy the values under 2018 and paste it under 2019
hope it helped
I thought this would be a no brainer. But I really need help to solve it.
I have a row of dates: 10 july 2020, 11 july 2020 and so on (Swedish excel).
Below each date are strings for example "FP". I wish to achieve a counter for each "FP" that is below a specific month of a year, such as july 2020.
The way I approached this was with
=COUNTIFS(G1:UG1;"*july 2020";G2:UG2;"FP")
However the * doesn't do what I want it to. Is there another way to do this?
Please help! :)
The dates are true dates and as such the july 2020 is just a format of a number and not actually there.
Instead BookEnd the date:
=COUNTIFS(G1:UG1;">="&DATE(2020;7;1);G1:UG1;"<"&DATE(2020;8;1);G2:UG2;"FP")
I have a table which represents the brands and stock for last 10 months. WHat I need is:
Identify the SKU which have been sold less than 10 (quantity) for last 10 months.
The problem is that sometimes the december stock is 6 but January stock is 31, and if I subtract that I get -25. And this alters the formula and I am unable to calculate the products which have been sold less than 10 times for last 10 months.
I use the formula like below :
=IF((D2-E2)+(E2-F2)+(F2-G2)+(G2-H2)+(H2-I2)+(I2-J2)+(J2-K2)+(K2-L2)+(L2-M2)<10;IF((D2-E2)+(E2-F2)+(F2-G2)+(G2-H2)+(H2-I2)+(I2-J2)+(J2-K2)+(K2-L2)+(L2-M2)>0;"Overstock";"No Overstock"))
Thanks in advance !
I think you should be able to use SUMPRODUCT in order to achieve your results:
=IF(E2>D2,SUMPRODUCT(E2:L2-F2:M2),SUMPRODUCT(D2:L2-E2:M2))
Afterwards, you can simply use =IF(AND(N2>0,N2<10),"Overstock","No Overstock") to mark the amount as Overstock or No Overstock.
Let me know if it works for you.
Kindly use SumIfs() formula for this issue
The problem that I'm facing currently is I have a start date and end date for multiple different items. What I want to do is be able to see when a report would be due at each given month that it's accounted for with a end report (+14 days from end date). For example:
The Lookup tab that I have for reference of the dates above to be able to match the months looks like this:
Now I'm having trouble creating a formula that would actually work with this. If I'm thinking correctly it would be something like,
IF Start Date != Start Month then IF Start Date is between March Dates, "Report", . . . IF End Date hits, add 14 days, then "End Report" on given month after 14 days.
So for the example above the outcome would look like the following:
This is the end result that I would want in the end. Due note that August for Battlefield 5 is supposed to be blank due to the game ending on 8/19/2018, +14 days for a end report: 9/2/2018 is the End Report date so their would not be a Report in August for that given scenario. (I think this is possible but not 100% sure for the August scenario)
I am open to any kind of formulas/Arrays/VBA's that would accomplish this task. I'm just having difficulty coming up with a solution for this that has been bugging me for a while, so any help is much appreciated!!
If anything needs to be further explained please let me know and I will do my best as an edit to this post.
-Maykid
Based on what you explained, you could just have a simple formula as such (no need for VBA):
LOCALISATION OF THIS FORMULA (E2) UNDER FEBRUARY 2018 in the picture attached
=IF(AND(MONTH($C2)=MONTH(E$1),MONTH($C2+14)=MONTH(F$1)),"",IF(AND(MONTH($C2+14)=MONTH(E$1),YEAR($C2+14)=YEAR(E$1)),"End Report",IF(AND($B2<E$1,($C2+14)>E$1),"Report","")))
And then you can drag this formula.
I hope it helps.
BR
I have a table like this:
Date Paid Days Late Date Paid Days Late Date Paid Days Late Date Paid Days Late Date Paid Days Late Date Paid Days Late
Utilities Admin Utilities Admin Utilities Admin
Company January January January January February February February February March March March March
Wayne Enterprises 2/15/2016 5 10-Feb 0 3/11/2016 1 4/15/2016 5 4/25/2016 15
Stark Industries 2/12/2016 3 2/8/2016 0 3/19/2016 10 3/8/2016 0 4/15/2016 5 4/1/2016 0
(I suggest though looking at the screenshot to see how it's laid out, as the pasting into here isn't very pretty, any tips? Here's a link to this on Google Spreadsheets).
How can I, in N4, create a formula that will count the number of months what have a late report (defined as any "Days Late" over 0). Obviously, I can do this:
=COUNTIFS(B1:M1,"Days Late",B4:M4,">0"), which returns 4.
For Wayne Enterprises, in March, both Utilities and Admin were paid late. However, this should only count as 1 month. How can I somehow add to my CountIfs() a statement that is like "if two values in the same month are greater than 0, treat as ONE month"?
I tried also doing something like:
=COUNTIFS(B1:M1,"Days Late",B4:M4,">0")/COUNTIFS(B1:M1,"Days Late",B4:M4,">0")+1
But that doesn't quite do the trick either. Thanks for any ideas. (Of course, if CountIfs() isn't the best way, I'm open to any other formulas! I have a sneaking suspicion SumProduct() might be an alternative) I'd prefer a formula solution over VBA, but if absolutely necessary, we can do a UDF perhaps.
Edit: I could create yet another helper column that compares a single month's Utilities and Admin, and if one or both are late, put 1, then just Countif() that column has 1 in it...but I'd rather not keep creating columns if I can help it, as I'll be doing this for 12 months.
Use this Array formula:
=SUM(IF(($B4:$M4>0)*($B$1:$M$1="Days Late"),1/COUNTIFS($B$3:$M$3,$B$3:$M$3,$B4:$M4,">0",$B$1:$M$1,"Days Late")))
Being an array formula it must be confirmed with Ctrl-Shift-Enter when exiting edit mode. If done properly excel will put {} around the formula.
As per your new data use this:
=SUM(IF(($B5:$BI5>0)*($B$1:$BI$1="Days past 10th of Following Month"),1/COUNTIFS($B$3:$BI$3,$B$3:$BI$3,$B5:$BI5,">0",$B$1:$BI$1,"Days past 10th of Following Month")))
The helper row of months in row 4 is not needed.
EDIT #2
My bad I forgot that when using formulas that return "" will cause an error so lets put in a check for that:
=SUM(IF(($B5:$BI5<>"")*($B5:$BI5>0)*($B$1:$BI$1=$AS$1),1/COUNTIFS($B$3:$BI$3,$B$3:$BI$3,$B5:$BI5,">0",$B$1:$BI$1,$AS$1)))