I have been a few days thinking about a problem in excel and I just can't seem to find a solution so I am trying this page for the first time.
The problem is as follows:
I have a set of columns that specify the name, type and model of different products. In addition I have a column with the date it was released and a column that says if the row is the latest in its specific name, type and model or not (they have to be the same to compare the dates).
I wanted to automate this column as I have done with others but I don't even know where to start. It seems incredibly difficult compared to the others I have done.
Sample:
Title Type Model Date Last date?
Fear Low B421 06/04/15 No
Fear Low B421 23/05/15 Yes
Hert Medium M12 07/11/14 No
If someone could help me with this I would really appreciate. Any clue or idea is helpful.
OK the formula you need in E2 would look like this:-
=IF(COUNTIFS(A$2:A$4,A2,B$2:B$4,B2,C$2:C$4,C2,D$2:D$4,">"&D2),"No","Yes")
if the data are in columns A to D with headers in row 1. Then pull it down to E3, E4 etc.
This says:-
'If there are any matching products with a later date, then this can't be the latest one, so put "No" '.
'If there are no matching products with a later date, then this must be the latest, so put "Yes"' (or at least joint latest, if there are two or more with the same date).
Related
I'm building some sample data to go through my libraries. I know there are programs that will do this for me, but I'm just trying to figure out for myself.
I have 6 columns. The first is the Name of the Movie, the second the date, 3-5 would be the hard disk it's on, 6 would be if it's in my library already.
Right now I'm trying to compare my library to the other disks, but the problem is when i see a title that could have multiple dates. I.e.
So if I do a simple =COUNTIF('PLEX Library'!A:A,A3) it would show in the library, which should match the name on the other sheets.
Plex Library
However, as you can see the Date is in column I but I could have multiple Movies that have 1993 in the year. So doing =COUNTIFS('PLEX Library'!A:A,A3,'PLEX Library'!I:AI,AI3) wouldn't work.
So I feel like I need to do a VLook up for this in a CountIFS statement but I'm not too sure.
COUNTIFS is good formula for what you need, because it counts if only all criteria are met. Your formula then would be:
=COUNTIFS('PLEX Library'!A:A,A3,'PLEX Library'!I:I,B3)
It will check if both name and date is same at the same time.
Example:
I'm not too sure how to word this problem so, I apologize for the vagueness. Here is what I am trying to do though:
I have a large Excel table with a ton of values, I however, only care about 3 columns. The three columns I have are "Project Name", "Active/Planned", and "Week of Month". Here is an example of some values I would have:
Project Name
Active/Planned
Week of Month
StoreProj
Active
2021-07 Jul-Wk1
SecProj
Planned
2021-07 Jul-Wk2
StoreProj
Active
2021-07 Jul-Wk1
Now, I have used a formula to get the number of projects based on a specific week month and avoiding duplicate values for the project name. The code I used returns an integer of the number of projects. Here is what I used:
=IFERROR(ROWS(UNIQUE(FILTER(Table[Project Name],Table[Week of Month]=2021-07 Jul-Wk1))), 0)
This works as intended. Now the issue I am running into is that I need to filter through these rows as I did previously, but now I need to include the "Active/Planned" column. So, I want to be able to see how many projects I have based off of the week of the month and return a number of projects (excluding duplicate names), but be able to filter through that integer output based off of the active/planned projects. So in a perfect scenario I can choose the week of month and if the project is "Active" or "Planned" and see the amount of projects I have.
This might be an easy fix so I apologize, I am just stumped, any help would be greatly appreciated. Thanks!
Work through that step by step, you've got the FILTER function which is giving data to the UNIQUE function, to the ROWS function, and then your IFERROR. However, the data about whether each line/row is 'Active' or 'planned' isn't passed out beyond the FILTER function, so can't be used by anything further on in the above sequence.
Boring theoretical advice out the way, try this;
=COUNT(IF(UNIQUE(FILTER( Table[[Project Name]:[Active/Planned]], Table[Week of Month] = "2021-07 Jul-wk1"))= "Active", 1))
Explanation:
FILTER(...) outputs records with the relevant date filter, however it outputs Table[[Project Name]:[Active/Planned]] - both columns, to ensure all relevant data is there.
UNIQUE(...) Then narrows that down to unique values, although by this stage I'm not 100% sure you need this.
IF(... = "Active", 1) then replaces the 'Active' outputs with 1s
COUNT() returns the number of cells in the above that contain a number (the 1s from the IF())
Yes, you can't use COUNTIF on arrays (and all except that last bullet point above are outputting arrays not single values) - and no, I didn't know that before attempting to answer this question, found it over at a different question!
What I'm trying to do is give a due date based on an input date, type of review, and department.
For example if the department is ABC and the review is retrospective, the due date will be the input date + 30 days.
But if the department is ABC and the review is concurrent, then the due date will be input date + 1 day.
I know I can concatenate the department and review into the vlookup table but I'm not so sure how to get the output to be the due date that I want.
Can anyone help?
EDIT:
Per the first answer below, I hashed out an input table with concatenated columns just in case I needed them. It is a bit more complicated than I originally thought.
Input table with date logic
I'd love to simply edit the source data but the report isn't readily available in the database. Could I still use the suggestions below?
Assuming you have a lookup table for the number of days to add depending upon the department and review type similar to the one below, you can use an INDEX/MATCH/MATCH and simply add it to the input date:
=$A2+INDEX($H$4:$J$5,MATCH($B2,$G$4:$G$5,0),MATCH($C2,$H$3:$J$3,0))
SOLUTION FOR AN ALTERNATIVE LOOKUP TABLE LAYOUT
If your layout table is more like as below, you can use a MINIFS formula (or MAXIFS if you would prefer):
=$A2+MINIFS($I$3:$I$8,$G$3:$G$8,$B2,$H$3:$H$8,$C2)
I am having a little difficulty conceptually understanding how to complete a task. Please forgive the context, but it will help.
I have a set of timetable information that contains the following
Date_Start (mm/dd/yyyy hh:mm:ss)
Date_End (mm/dd/yyyy hh:mm:ss)
Activity_location (String, code, example: B/B/012)
Other information that is not important
We have performed an audit (people going and doing a manual check on room occupancy). This audit was done using a google form which has now produced a spreadsheet. Unfortunately this doesn't quite match the format of the other one and instead contains:
Date
Time
B/B/012
B/B/011
... etc.
The problem is that each room is an individual column, regardless of if it was audited, which produces .... a lot of columns. I have already combined the Date and Time from the second dataset to produce a comparable datetime.
My task it to compare the information, so I have the timetable data (what should have happened) and I have the audit information (what did happen) and I need to find any discrepancies.
I am just having a little difficulty understanding how I might get these datasets into a format where I can compare them. I would really appreciate any help you might be able to give.
If Excel and you do have the dates (stripped from unneeded characters) in a column, you simply need to tell Excel how to interpret these values as dates. For instance, if you have the value 1/3/16, Excel may interpret it as March 1st, 2016 or Jan 3td, 2016.
To tell Excel how to interpret dates, you select the column (all cells in the column having values), right-click and select Format cells.... There, you can tell Excel that the value should be read as dd/mm/yy or mm/dd/yy.
Once you have Excel fully aware of the meaning of those dates, you can simply compare them (e.g. if(B3>G3... will check if the date in B3 is later than that in G3).
Hope this assists you to proceed.
UPDATE
Based on the exchange through comments, here is my final answer.
If you need to establish a relation (say between spreadsheet "A" and spreadsheet "B") when not only there is a on-to-one relation between columns/rows of both sheets, and (even worse) the one-to-many correlation is not predictable (meaning, in one case you have a one-to-one, in the next a one-to-4 and in the next a one-to-17), the only solution is either pivoting one of the tables or writing some MACROS.
I don't see any other way our of this. Sorry.
I have a worksheet, in where I need a search that does more than one query. The problem I am running into is this:
On the workbook there are two tabs, the first is Jobs, the second is OOR. In OOR there are multiple columns empty, Order Qty., Orig Promise Date, and Shop Order.
Now I know there are duplicates, and this is fine, what I am looking at now is to use Column B in OOR is a refrence. So in this case use B3 as the refrence point. which is a partial number of 48900421 Rev 2. What I want to do is this, use two refrence points.
I want to look up B3 in OOR, and use two points of refrence to gurantee the correct job is refrenced. Those two columns to refrence is in Jobs. The first is Column B which will always equal Dakota Systems, Inc., and the other will reference Column C, but this is where I don't know what to do here, I since C3 in OOR only shows 48900421, it will never find 48900421 Rev 2I thought about using something like this:
=IFERROR(INDEX(Jobs!$E:$E,MATCH(1,INDEX((OOR!$C:$C=$B3)*(Jobs!$C:$C="Dakota Systems, Inc."),1),0)),"")
But for some reason I am getting a blank when I don't think I should be. I'm loosing my sanity this late in the week, can someone help?
https://dl.dropbox.com/u/3327208/Excel/twosearches.xlsx
You don't seem to be referencing the right columns....and also you need a zero in the second INDEX function, not a 1
Try this version in in OOR!I3 copied down, using ISNUMBER(FIND to find your part number within other text:
=IFERROR(INDEX(Jobs!E$3:E$1000,MATCH(1,INDEX(ISNUMBER(FIND(B3,Jobs!C$3:C$1000))*(Jobs!B$3:B$1000="Dakota Systems, Inc."),0),0)),"")
format in required date format
Revised re comment below:
=IFERROR(INDEX(Jobs!E$3:E$1000,MATCH(1,INDEX(ISNUMBER(FIND(B3,Jobs!C$3:C$1000))*(Jobs!B$3:B$1000="Dakota Systems, Inc.")*(Jobs!A$3:A$1000=M3),0),0)),"")