In column E I have a list of 400 first names and in column F I have a list of their last names. How do I merge the first letter with the last name in another column. Column G is what I want in the below example.
Example
ColE ColF ColG
John Smith JSmith
Mike Tomas MTomas
Jill Lake JLake
Use the LEFT() function and the ampersand to concatenate
=LEFT(e1,1)&f1
This formula in column G will get what you want:
=CONCATENATE(LEFT(E1,1),F1)
=CONCATENATE(LEFT(E2,1),F2)
=CONCATENATE(LEFT(E3,1),F3)
...
In Column G, try
left(E1,1) & F1
Related
Column A
Camisi, Terry
Goodman, Harris
Kostin, Heidi
Malachi, Lorrie
Column B
Terry
Harris
Lorri
Heidi
I'd like to create a formula that looks for a partial match of a name in two columns (Column A and Column B) in the same sheet, and if there is a partial match between the two names, it returns the value of Column B in Column C. Pls note, names are not in sequence.
#Harun24HR, Please see modified question below:
Column A (Last Name, First Name)
Camisi, Terry
Goodman, Harris
Kostin, Heidi
Malachi, Lorrie
Column B (Last Name)
Goodman
Malachi
Kostin
Camisi
Column C (First Name)
Harris
Lorri
Heidi
Terry
I have three columns, I need to compare Column A vs. Column B & C to find a partial match. If there's a match Name from Column A should be visible in Column D. Please advise. Thx
You can try MATCH() function with wildcard matching.
=INDEX($B$1:$B$4,MATCH("*"&B1&"*",$A$1:$A$4,0))
Or below one
=IF(ISNUMBER(MATCH("*"&B1&"*",$A$1:$A$4,0)),B1,"")
I am having issues making the function Index and Match work together.
Here's my data:
A B C D E
ShortName Fullname NumberID Shortname
Craig Craig David 54 John
John John Long 53 Enrique
Raymond Raymond Short 23 Craig
Bill Bill Bush 21 Raymond
Here, the column "C" is blank. Basically, I merged two data sheets together (column A and B with column D and E). What I would like is to have the NumberID in column C associated with the shortname in A. Here the NumberID in column D is associated with the shortname in column E.
So far I have tried Vlookup but it is not working. I have tried also Index and Match function but it ain't working either.
What I have:
INDEX(D:E;MATCH(A2;E;0);1)
I am using Excel in french that's why I used ";" in formula). Does anyone have a solution ?
You were close, Column Reference is E:E not E and you do not need to reference both columns in the INDEX, just the output.
=INDEX(D:D;MATCH(A2;E:E;0))
All,
I've taken a browse around and I've been unable to nail down the formula I'm looking for. I'm a bit new to Excel expressions, so this is all part of the learning process.
My quandary:
I have a list of names in an Excel spreadsheet - some have two components and some have three. I need all names to have only two components - if they have three, then the first two components need to be combined.
Here is my workflow:
IF cell 3 is occupied, append the content of cell 2 to the end of cell 1 IN cell 1. Then, assuming cell 2 is now blank, move the content of cell 3 to cell 2. Else, do nothing.
So my input might be (assuming each group of characters is in its own cell):
JOHN SMITH
JOHN DOE SMITH
BARRY JOHNSON
RICHARD P RICKSON
JACK JACK GILES
My output would be:
JOHN SMITH
JOHNDOE SMITH
BARRY JOHNSON
RICHARDP RICKSON
JACKJACK GILES
What's your take on this?
Assuming your data is in columns A, B, and C, this will put the correct output in columns D and E.
In column D:
=IF(ISBLANK(C1),A1,CONCAT(A1,B1))
In column E:
=IF(ISBLANK(C1),B1,C1)
I have one example table with the following data in Sheet1 with the following random data
------A ----------------- B ----------------------C ------------------------D
1 --First--------------Last-----------------Start Date--------------End Date
2 --John--------------Smith--------------08/08/2014------------01/01/2015
3---John--------------Smith--------------08/11/2014------------17/11/2014
4---John--------------Smith--------------06/06/2014------------23/12/2014
5---Abel--------------Jones--------------14/05/2014------------29/04/2015
6---Abel--------------Jones--------------04/07/2014------------26/04/2015
Then I have another table in Sheet2
------A ----------------- B ----------------------C ------------------------D
1 --First--------------Last-----------------Start Date--------------End Date
2 --John--------------Smith---------------------------------------------------
3---John--------------Smith---------------------------------------------------
4---John--------------Smith---------------------------------------------------
5---Abel--------------Jones---------------------------------------------------
6---Abel--------------Jones---------------------------------------------------
I am using INDEX MATCH to transfer the data between the two sheets.
=INDEX(Sheet1!$C:$C,
MATCH(1,INDEX((Sheet1!$A:$A=$A3)*(Sheet1!$B:$B=$B3),0),0))
To populate column C with the start dates from Sheet1.
=INDEX(Sheet1!$D:$D,
MATCH(1,INDEX((Sheet1!$A:$A=$A3)*(Sheet1!$B:$B=$B3),0),0))
and this to populate column D with the end dates.
The problem is, when I perform this INDEX MATCH function, for a duplicate name, it will only copy over the first value. So this formula will paste 08/08/2014 into all 'John Smith' Start dates in column C of Sheet2.
How do I obtain all values so that C2 should be 08/08/2014, C3 should be 08/11/2014, C4 should be 06/06/2014 etc.
One solution would be to insert a column in both sheets with a "running count" of instances of the same name. For example, insert col C and in C2 enter =IF(A2&B2 = A1&B1, C1+1, 1). This starts the count at 1 if the concatenated first and last name is new, and increases the previous count by 1 if not. So you would have
First Last Count by Person
John Smith 1
John Smith 2
John Smith 3
Abel Jones 1
Abel Jones 2
George Washington 1
Thomas Jefferson 1
Thomas Jefferson 2
You can then add this column to your MATCH() function (and change the lookup column as necessary).
Edit: It is worth noting that this requires your raw data is sorted by name.
You can narrow the $A:$A refferances to something like $Ax+1:$Ay where y = last row of your excel sheet and x is position of previous occurance of this name/surname (you could store this in some dummy column).
I have an Excel sheet with first names in Column A and surnames in Column B. I want to create a third Column C that contains the first character from the first name and adds it to the surname, creating first initial + surname.
First Name Last Name Combined Name
John Smith jsmith
How can I do this using Excel?
=CONCATENATE(LEFT(A1,1), B1)
Assuming A1 holds 1st names; B1 Last names
Personally I like the & function for this
Assuming that you are using cells A1 and A2 for John Smith
=left(a1,1) & b1
If you want to add text between, for example a period
=left(a1,1) & "." & b1
Use following formula:
=CONCATENATE(LOWER(MID(A1,1,1)),LOWER( B1))
for
Josh Smith = jsmith
note that A1 contains name and B1 contains surname
This is what formula I used in order to get the first letter of the first name and first letter of the last name from 2 different cells into one:
=CONCATENATE(LEFT(F10,1),LEFT(G10,1))
Lee Ackerman = LA
Not sure why no one is using semicolons. This is how it works for me:
=CONCATENATE(LEFT(A1;1); B1)
Solutions with comma produce an error in Excel.
QUESTION was: suppose T john is to be converted john T, how to change in excel?
If text "T john" is in cell A1
=CONCATENATE(RIGHT(A1,LEN(A1)-2)," ",LEFT(A1,1))
and with a nod to the & crowd
=RIGHT(A1,LEN(A1)-2)&" "&LEFT(A1,1)
takes the right part of the string excluding the first 2 characters, adds a space, adds the first character.